scripts/metadata.pl

   1 #!/usr/bin/env perl
   2 use FindBin;
   3 use lib "$FindBin::Bin";
   4 use strict;
   5 use metadata;
   6
   7 my %board;
   8
   9 sub confstr($) {
  10         my $conf = shift;
  11         $conf =~ tr#/\.\-/#___#;
  12         return $conf;
  13 }
  14
  15 sub parse_target_metadata() {
  16         my $file = shift @ARGV;
  17         my ($target, @target, $profile);
  18         my %target;
  19
  20         open FILE, "<$file" or do {
  21                 warn "Can't open file '$file': $!\n";
  22                 return;
  23         };
  24         while (<FILE>) {
  25                 chomp;
  26                 /^Target:\s*(.+)\s*$/ and do {
  27                         my $name = $1;
  28                         $target = {
  29                                 id => $name,
  30                                 board => $name,
  31                                 boardconf => confstr($name),
  32                                 conf => confstr($name),
  33                                 profiles => [],
  34                                 features => [],
  35                                 depends => [],
  36                                 subtargets => []
  37                         };
  38                         push @target, $target;
  39                         $target{$name} = $target;
  40                         if ($name =~ /([^\/]+)\/([^\/]+)/) {
  41                                 push @{$target{$1}->{subtargets}}, $2;
  42                                 $target->{board} = $1;
  43                                 $target->{boardconf} = confstr($1);
  44                                 $target->{subtarget} = 1;
  45                                 $target->{parent} = $target{$1};
  46                         }
  47                 };
  48                 /^Target-Kernel:\s*(\d+\.\d+)\s*$/ and $target->{kernel} = $1;
  49                 /^Target-Name:\s*(.+)\s*$/ and $target->{name} = $1;
  50                 /^Target-Path:\s*(.+)\s*$/ and $target->{path} = $1;
  51                 /^Target-Arch:\s*(.+)\s*$/ and $target->{arch} = $1;
  52                 /^Target-Features:\s*(.+)\s*$/ and $target->{features} = [ split(/\s+/, $1) ];
  53                 /^Target-Depends:\s*(.+)\s*$/ and $target->{depends} = [ split(/\s+/, $1) ];
  54                 /^Target-Description:/ and $target->{desc} = get_multiline(*FILE);
  55                 /^Target-Optimization:\s*(.+)\s*$/ and $target->{cflags} = $1;
  56                 /^Linux-Version:\s*(.+)\s*$/ and $target->{version} = $1;
  57                 /^Linux-Release:\s*(.+)\s*$/ and $target->{release} = $1;
  58                 /^Linux-Kernel-Arch:\s*(.+)\s*$/ and $target->{karch} = $1;
  59                 /^Default-Packages:\s*(.+)\s*$/ and $target->{packages} = [ split(/\s+/, $1) ];
  60                 /^Target-Profile:\s*(.+)\s*$/ and do {
  61                         $profile = {
  62                                 id => $1,
  63                                 name => $1,
  64                                 packages => []
  65                         };
  66                         push @{$target->{profiles}}, $profile;
  67                 };
  68                 /^Target-Profile-Name:\s*(.+)\s*$/ and $profile->{name} = $1;
  69                 /^Target-Profile-Packages:\s*(.*)\s*$/ and $profile->{packages} = [ split(/\s+/, $1) ];
  70                 /^Target-Profile-Description:\s*(.*)\s*/ and $profile->{desc} = get_multiline(*FILE);
  71                 /^Target-Profile-Config:/ and $profile->{config} = get_multiline(*FILE, "\t");
  72                 /^Target-Profile-Kconfig:/ and $profile->{kconfig} = 1;
  73         }
  74         close FILE;
  75         foreach my $target (@target) {
  76                 next if @{$target->{subtargets}} > 0;
  77                 @{$target->{profiles}} > 0 or $target->{profiles} = [
  78                         {
  79                                 id => 'Default',
  80                                 name => 'Default',
  81                                 packages => []
  82                         }
  83                 ];
  84         }
  85         return @target;
  86 }
  87
  88 sub gen_kconfig_overrides() {
  89         my %config;
  90         my %kconfig;
  91         my $package;
  92         my $pkginfo = shift @ARGV;
  93         my $cfgfile = shift @ARGV;
  94
  95         # parameter 2: build system config
  96         open FILE, "<$cfgfile" or return;
  97         while (<FILE>) {
  98                 /^(CONFIG_.+?)=(.+)$/ and $config{$1} = 1;
  99         }
 100         close FILE;
 101
 102         # parameter 1: package metadata
 103         open FILE, "<$pkginfo" or return;
 104         while (<FILE>) {
 105                 /^Package:\s*(.+?)\s*$/ and $package = $1;
 106                 /^Kernel-Config:\s*(.+?)\s*$/ and do {
 107                         my @config = split /\s+/, $1;
 108                         foreach my $config (@config) {
 109                                 my $val = 'm';
 110                                 my $override;
 111                                 if ($config =~ /^(.+?)=(.+)$/) {
 112                                         $config = $1;
 113                                         $override = 1;
 114                                         $val = $2;
 115                                 }
 116                                 if ($config{"CONFIG_PACKAGE_$package"} and ($config ne 'n')) {
 117                                         $kconfig{$config} = $val;
 118                                 } elsif (!$override) {
 119                                         $kconfig{$config} or $kconfig{$config} = 'n';
 120                                 }
 121                         }
 122                 };
 123         };
 124         close FILE;
 125
 126         foreach my $kconfig (sort keys %kconfig) {
 127                 if ($kconfig{$kconfig} eq 'n') {
 128                         print "# $kconfig is not set\n";
 129                 } else {
 130                         print "$kconfig=$kconfig{$kconfig}\n";
 131                 }
 132         }
 133 }
 134
 135 sub merge_package_lists($$) {
 136         my $list1 = shift;
 137         my $list2 = shift;
 138         my @l = ();
 139         my %pkgs;
 140
 141         foreach my $pkg (@$list1, @$list2) {
 142                 $pkgs{$pkg} = 1;
 143         }
 144         foreach my $pkg (keys %pkgs) {
 145                 push @l, $pkg unless ($pkg =~ /^-/ or $pkgs{"-$pkg"});
 146         }
 147         return sort(@l);
 148 }
 149
 150 sub target_config_features(@) {
 151         my $ret;
 152
 153         while ($_ = shift @_) {
 154                 /broken/ and $ret .= "\tdepends BROKEN\n";
 155                 /audio/ and $ret .= "\tselect AUDIO_SUPPORT\n";
 156                 /display/ and $ret .= "\tselect DISPLAY_SUPPORT\n";
 157                 /gpio/ and $ret .= "\tselect GPIO_SUPPORT\n";
 158                 /pci/ and $ret .= "\tselect PCI_SUPPORT\n";
 159                 /pcie/ and $ret .= "\tselect PCIE_SUPPORT\n";
 160                 /usb/ and $ret .= "\tselect USB_SUPPORT\n";
 161                 /pcmcia/ and $ret .= "\tselect PCMCIA_SUPPORT\n";
 162                 /squashfs/ and $ret .= "\tselect USES_SQUASHFS\n";
 163                 /jffs2/ and $ret .= "\tselect USES_JFFS2\n";
 164                 /ext2/ and $ret .= "\tselect USES_EXT2\n";
 165                 /tgz/ and $ret .= "\tselect USES_TGZ\n";
 166                 /cpiogz/ and $ret .= "\tselect USES_CPIOGZ\n";
 167                 /ubifs/ and $ret .= "\tselect USES_UBIFS\n";
 168                 /fpu/ and $ret .= "\tselect HAS_FPU\n";
 169                 /ramdisk/ and $ret .= "\tselect USES_INITRAMFS\n";
 170                 /powerpc64/ and $ret .= "\tselect powerpc64\n";
 171                 /nommu/ and $ret .= "\tselect NOMMU\n";
 172         }
 173         return $ret;
 174 }
 175
 176 sub target_name($) {
 177         my $target = shift;
 178         my $parent = $target->{parent};
 179         if ($parent) {
 180                 return $target->{parent}->{name}." - ".$target->{name};
 181         } else {
 182                 return $target->{name};
 183         }
 184 }
 185
 186 sub kver($) {
 187         my $v = shift;
 188         $v =~ tr/\./_/;
 189         $v =~ /(\d+_\d+_\d+)(_\d+)?/ and $v = $1;
 190         return $v;
 191 }
 192
 193 sub print_target($) {
 194         my $target = shift;
 195         my $features = target_config_features(@{$target->{features}});
 196         my $help = $target->{desc};
 197         my $kernel = $target->{kernel};
 198         my $confstr;
 199         $kernel =~ tr/./_/;
 200
 201         chomp $features;
 202         $features .= "\n";
 203         if ($help =~ /\w+/) {
 204                 $help =~ s/^\s*/\t  /mg;
 205                 $help = "\thelp\n$help";
 206         } else {
 207                 undef $help;
 208         }
 209
 210         my $v = kver($target->{version});
 211         if (@{$target->{subtargets}} == 0) {
 212         $confstr = <<EOF;
 213 config TARGET_$target->{conf}
 214         bool "$target->{name}"
 215         select LINUX_$kernel
 216         select LINUX_$v
 217 EOF
 218         }
 219         else {
 220                 $confstr = <<EOF;
 221 config TARGET_$target->{conf}
 222         bool "$target->{name}"
 223 EOF
 224         }
 225         if ($target->{subtarget}) {
 226                 $confstr .= "\tdepends TARGET_$target->{boardconf}\n";
 227         }
 228         if (@{$target->{subtargets}} > 0) {
 229                 $confstr .= "\tselect HAS_SUBTARGETS\n";
 230         }
 231
 232         if ($target->{arch} =~ /\w/) {
 233                 $confstr .= "\tselect $target->{arch}\n";
 234         }
 235         foreach my $dep (@{$target->{depends}}) {
 236                 my $mode = "depends";
 237                 my $flags;
 238                 my $name;
 239
 240                 $dep =~ /^([@\+\-]+)(.+)$/;
 241                 $flags = $1;
 242                 $name = $2;
 243
 244                 next if $name =~ /:/;
 245                 $flags =~ /-/ and $mode = "deselect";
 246                 $flags =~ /\+/ and $mode = "select";
 247                 $flags =~ /@/ and $confstr .= "\t$mode $name\n";
 248         }
 249         $confstr .= $features;
 250         $confstr .= "$help\n\n";
 251         print $confstr;
 252 }
 253
 254 sub gen_target_config() {
 255         my @target = parse_target_metadata();
 256         my %defaults;
 257
 258         my @target_sort = sort {
 259                 target_name($a) cmp target_name($b);
 260         } @target;
 261
 262
 263         print <<EOF;
 264 choice
 265         prompt "Target System"
 266         default TARGET_brcm_2_4
 267         reset if !DEVEL
 268
 269 EOF
 270
 271         foreach my $target (@target_sort) {
 272                 next if $target->{subtarget};
 273                 print_target($target);
 274         }
 275
 276         print <<EOF;
 277 endchoice
 278
 279 choice
 280         prompt "Subtarget" if HAS_SUBTARGETS
 281
 282 EOF
 283         foreach my $target (@target) {
 284                 next unless $target->{subtarget};
 285                 print_target($target);
 286         }
 287
 288 print <<EOF;
 289 endchoice
 290
 291 choice
 292         prompt "Target Profile"
 293
 294 EOF
 295
 296         foreach my $target (@target) {
 297                 my $profiles = $target->{profiles};
 298
 299                 foreach my $profile (@$profiles) {
 300                         print <<EOF;
 301 config TARGET_$target->{conf}_$profile->{id}
 302         bool "$profile->{name}"
 303         depends TARGET_$target->{conf}
 304 $profile->{config}
 305 EOF
 306                         $profile->{kconfig} and print "\tselect PROFILE_KCONFIG\n";
 307                         my @pkglist = merge_package_lists($target->{packages}, $profile->{packages});
 308                         foreach my $pkg (@pkglist) {
 309                                 print "\tselect DEFAULT_$pkg\n";
 310                                 $defaults{$pkg} = 1;
 311                         }
 312                         my $help = $profile->{desc};
 313                         if ($help =~ /\w+/) {
 314                                 $help =~ s/^\s*/\t  /mg;
 315                                 $help = "\thelp\n$help";
 316                         } else {
 317                                 undef $help;
 318                         }
 319                         print "$help\n";
 320                 }
 321         }
 322
 323         print <<EOF;
 324 endchoice
 325
 326 config HAS_SUBTARGETS
 327         bool
 328
 329 config TARGET_BOARD
 330         string
 331
 332 EOF
 333         foreach my $target (@target) {
 334                 $target->{subtarget} or print "\t\tdefault \"".$target->{board}."\" if TARGET_".$target->{conf}."\n";
 335         }
 336         print <<EOF;
 337
 338 config DEFAULT_TARGET_OPTIMIZATION
 339         string
 340 EOF
 341         foreach my $target (@target) {
 342                 next if @{$target->{subtargets}} > 0;
 343                 print "\tdefault \"".$target->{cflags}."\" if TARGET_".$target->{conf}."\n";
 344         }
 345         print "\tdefault \"-Os -pipe -funit-at-a-time\"\n";
 346
 347         my %kver;
 348         foreach my $target (@target) {
 349                 my $v = kver($target->{version});
 350                 next if $kver{$v};
 351                 $kver{$v} = 1;
 352                 print <<EOF;
 353
 354 config LINUX_$v
 355         bool
 356
 357 EOF
 358         }
 359         foreach my $def (sort keys %defaults) {
 360                 print "\tconfig DEFAULT_".$def."\n";
 361                 print "\t\tbool\n\n";
 362         }
 363 }
 364
 365 my %dep_check;
 366 sub __find_package_dep($$) {
 367         my $pkg = shift;
 368         my $name = shift;
 369         my $deps = ($pkg->{vdepends} or $pkg->{depends});
 370
 371         return 0 unless defined $deps;
 372         foreach my $dep (@{$deps}) {
 373                 next if $dep_check{$dep};
 374                 $dep_check{$dep} = 1;
 375                 return 1 if $dep eq $name;
 376                 return 1 if ($package{$dep} and (__find_package_dep($package{$dep},$name) == 1));
 377         }
 378         return 0;
 379 }
 380
 381 # wrapper to avoid infinite recursion
 382 sub find_package_dep($$) {
 383         my $pkg = shift;
 384         my $name = shift;
 385
 386         %dep_check = ();
 387         return __find_package_dep($pkg, $name);
 388 }
 389
 390 sub package_depends($$) {
 391         my $a = shift;
 392         my $b = shift;
 393         my $ret;
 394
 395         return 0 if ($a->{submenu} ne $b->{submenu});
 396         if (find_package_dep($a, $b->{name}) == 1) {
 397                 $ret = 1;
 398         } elsif (find_package_dep($b, $a->{name}) == 1) {
 399                 $ret = -1;
 400         } else {
 401                 return 0;
 402         }
 403         return $ret;
 404 }
 405
 406 sub mconf_depends {
 407         my $pkgname = shift;
 408         my $depends = shift;
 409         my $only_dep = shift;
 410         my $res;
 411         my $dep = shift;
 412         my $seen = shift;
 413         my $parent_condition = shift;
 414         $dep or $dep = {};
 415         $seen or $seen = {};
 416
 417         $depends or return;
 418         my @depends = @$depends;
 419         foreach my $depend (@depends) {
 420                 my $m = "depends";
 421                 my $flags = "";
 422                 $depend =~ s/^([@\+]+)// and $flags = $1;
 423                 my $vdep;
 424                 my $condition = $parent_condition;
 425
 426                 if ($depend =~ /^(.+):(.+)$/) {
 427                         if ($1 ne "PACKAGE_$pkgname") {
 428                                 if ($condition) {
 429                                         $condition = "$condition && $1";
 430                                 } else {
 431                                         $condition = $1;
 432                                 }
 433                         }
 434                         $depend = $2;
 435                 }
 436                 next if $seen->{$depend};
 437                 next if $package{$depend} and $package{$depend}->{buildonly};
 438                 $seen->{$depend} = 1;
 439                 if ($vdep = $package{$depend}->{vdepends}) {
 440                         $depend = join("||", map { "PACKAGE_".$_ } @$vdep);
 441                 } else {
 442                         $flags =~ /\+/ and do {
 443                                 # Menuconfig will not treat 'select FOO' as a real dependency
 444                                 # thus if FOO depends on other config options, these dependencies
 445                                 # will not be checked. To fix this, we simply emit all of FOO's
 446                                 # depends here as well.
 447                                 $package{$depend} and mconf_depends($pkgname, $package{$depend}->{depends}, 1, $dep, $seen, $condition);
 448
 449                                 $m = "select";
 450                                 next if $only_dep;
 451                         };
 452                         $flags =~ /@/ or $depend = "PACKAGE_$depend";
 453                         if ($condition) {
 454                                 if ($m =~ /select/) {
 455                                         $depend = "$depend if $condition";
 456                                 } else {
 457                                         $depend = "!($condition) || $depend";
 458                                 }
 459                         }
 460                 }
 461                 $dep->{$depend} =~ /select/ or $dep->{$depend} = $m;
 462         }
 463         foreach my $depend (keys %$dep) {
 464                 my $m = $dep->{$depend};
 465                 $res .= "\t\t$m $depend\n";
 466         }
 467         return $res;
 468 }
 469
 470 sub print_package_config_category($) {
 471         my $cat = shift;
 472         my %menus;
 473         my %menu_dep;
 474
 475         return unless $category{$cat};
 476
 477         print "menu \"$cat\"\n\n";
 478         my %spkg = %{$category{$cat}};
 479
 480         foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
 481                 foreach my $pkg (@{$spkg{$spkg}}) {
 482                         next if $pkg->{buildonly};
 483                         my $menu = $pkg->{submenu};
 484                         if ($menu) {
 485                                 $menu_dep{$menu} or $menu_dep{$menu} = $pkg->{submenudep};
 486                         } else {
 487                                 $menu = 'undef';
 488                         }
 489                         $menus{$menu} or $menus{$menu} = [];
 490                         push @{$menus{$menu}}, $pkg;
 491                 }
 492         }
 493         my @menus = sort {
 494                 ($a eq 'undef' ?  1 : 0) or
 495                 ($b eq 'undef' ? -1 : 0) or
 496                 ($a cmp $b)
 497         } keys %menus;
 498
 499         foreach my $menu (@menus) {
 500                 my @pkgs = sort {
 501                         package_depends($a, $b) or
 502                         ($a->{name} cmp $b->{name})
 503                 } @{$menus{$menu}};
 504                 if ($menu ne 'undef') {
 505                         $menu_dep{$menu} and print "if $menu_dep{$menu}\n";
 506                         print "menu \"$menu\"\n";
 507                 }
 508                 foreach my $pkg (@pkgs) {
 509                         my $title = $pkg->{name};
 510                         my $c = (72 - length($pkg->{name}) - length($pkg->{title}));
 511                         if ($c > 0) {
 512                                 $title .= ("." x $c). " ". $pkg->{title};
 513                         }
 514                         print "\t";
 515                         $pkg->{menu} and print "menu";
 516                         print "config PACKAGE_".$pkg->{name}."\n";
 517                         print "\t\t".($pkg->{tristate} ? 'tristate' : 'bool')." \"$title\"\n";
 518                         print "\t\tdefault y if DEFAULT_".$pkg->{name}."\n";
 519                         foreach my $default (split /\s*,\s*/, $pkg->{default}) {
 520                                 print "\t\tdefault $default\n";
 521                         }
 522                         print mconf_depends($pkg->{name}, $pkg->{depends}, 0);
 523                         print "\t\thelp\n";
 524                         print $pkg->{description};
 525                         print "\n";
 526
 527                         $pkg->{config} and print $pkg->{config}."\n";
 528                 }
 529                 if ($menu ne 'undef') {
 530                         print "endmenu\n";
 531                         $menu_dep{$menu} and print "endif\n";
 532                 }
 533         }
 534         print "endmenu\n\n";
 535
 536         undef $category{$cat};
 537 }
 538
 539 sub print_package_features() {
 540         keys %features > 0 or return;
 541         print "menu \"Package features\"\n";
 542         foreach my $n (keys %features) {
 543                 my @features = sort { $b->{priority} <=> $a->{priority} or $a->{title} cmp $b->{title} } @{$features{$n}};
 544                 print <<EOF;
 545 choice
 546         prompt "$features[0]->{target_title}"
 547         default FEATURE_$features[0]->{name}
 548 EOF
 549
 550                 foreach my $feature (@features) {
 551                         print <<EOF;
 552         config FEATURE_$feature->{name}
 553                 bool "$feature->{title}"
 554 EOF
 555                         $feature->{description} =~ /\w/ and do {
 556                                 print "\t\thelp\n".$feature->{description}."\n";
 557                         };
 558                 }
 559                 print "endchoice\n"
 560         }
 561         print "endmenu\n\n";
 562 }
 563
 564 sub gen_package_config() {
 565         parse_package_metadata($ARGV[0]) or exit 1;
 566         print "menuconfig IMAGEOPT\n\tbool \"Image configuration\"\n\tdefault n\n";
 567         foreach my $preconfig (keys %preconfig) {
 568                 foreach my $cfg (keys %{$preconfig{$preconfig}}) {
 569                         my $conf = $preconfig{$preconfig}->{$cfg}->{id};
 570                         $conf =~ tr/\.-/__/;
 571                         print <<EOF
 572         config UCI_PRECONFIG_$conf
 573                 string "$preconfig{$preconfig}->{$cfg}->{label}" if IMAGEOPT
 574                 depends PACKAGE_$preconfig
 575                 default "$preconfig{$preconfig}->{$cfg}->{default}"
 576
 577 EOF
 578                 }
 579         }
 580         print "source \"package/*/image-config.in\"\n";
 581         if (scalar glob "package/feeds/*/*/image-config.in") {
 582             print "source \"package/feeds/*/*/image-config.in\"\n";
 583         }
 584         print_package_features();
 585         print_package_config_category 'Base system';
 586         foreach my $cat (keys %category) {
 587                 print_package_config_category $cat;
 588         }
 589 }
 590
 591 sub get_conditional_dep($$) {
 592         my $condition = shift;
 593         my $depstr = shift;
 594         if ($condition) {
 595                 if ($condition =~ /^!(.+)/) {
 596                         return "\$(if \$(CONFIG_$1),,$depstr)";
 597                 } else {
 598                         return "\$(if \$(CONFIG_$condition),$depstr)";
 599                 }
 600         } else {
 601                 return $depstr;
 602         }
 603 }
 604
 605 sub gen_package_mk() {
 606         my %conf;
 607         my %dep;
 608         my %done;
 609         my $line;
 610
 611         parse_package_metadata($ARGV[0]) or exit 1;
 612         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 613                 my $config;
 614                 my $pkg = $package{$name};
 615                 my @srcdeps;
 616
 617                 next if defined $pkg->{vdepends};
 618
 619                 if ($ENV{SDK}) {
 620                         $conf{$pkg->{src}} or do {
 621                                 $config = 'm';
 622                                 $conf{$pkg->{src}} = 1;
 623                         };
 624                 } else {
 625                         $config = "\$(CONFIG_PACKAGE_$name)"
 626                 }
 627                 if ($config) {
 628                         $pkg->{buildonly} and $config = "";
 629                         print "package-$config += $pkg->{subdir}$pkg->{src}\n";
 630                         if ($pkg->{variant}) {
 631                                 print "\$(curdir)/$pkg->{subdir}$pkg->{src}/variants += \$(if $config,$pkg->{variant})\n"
 632                         }
 633                         $pkg->{prereq} and print "prereq-$config += $pkg->{subdir}$pkg->{src}\n";
 634                 }
 635
 636                 next if $done{$pkg->{src}};
 637                 $done{$pkg->{src}} = 1;
 638
 639                 if (@{$pkg->{buildtypes}} > 0) {
 640                         print "buildtypes-$pkg->{subdir}$pkg->{src} = ".join(' ', @{$pkg->{buildtypes}})."\n";
 641                 }
 642
 643                 foreach my $spkg (@{$srcpackage{$pkg->{src}}}) {
 644                         foreach my $dep (@{$spkg->{depends}}, @{$spkg->{builddepends}}) {
 645                                 $dep =~ /@/ or do {
 646                                         $dep =~ s/\+//g;
 647                                         push @srcdeps, $dep;
 648                                 };
 649                         }
 650                 }
 651                 foreach my $type (@{$pkg->{buildtypes}}) {
 652                         my @extra_deps;
 653                         my %deplines;
 654
 655                         next unless $pkg->{"builddepends/$type"};
 656                         foreach my $dep (@{$pkg->{"builddepends/$type"}}) {
 657                                 my $suffix = "";
 658                                 my $condition;
 659
 660                                 if ($dep =~ /^(.+):(.+)/) {
 661                                         $condition = $1;
 662                                         $dep = $2;
 663                                 }
 664                                 if ($dep =~ /^(.+)(\/.+)/) {
 665                                         $dep = $1;
 666                                         $suffix = $2;
 667                                 }
 668                                 my $pkg_dep = $package{$dep};
 669                                 next unless $pkg_dep;
 670
 671                                 my $idx = "";
 672                                 if (defined $pkg_dep->{src}) {
 673                                         $idx = $pkg_dep->{subdir}.$pkg_dep->{src};
 674                                 } elsif (defined($srcpackage{$dep})) {
 675                                         $idx = $subdir{$dep}.$dep;
 676                                 }
 677                                 my $depstr = "\$(curdir)/$idx$suffix/compile";
 678                                 my $depline = get_conditional_dep($condition, $depstr);
 679                                 if ($depline) {
 680                                         $deplines{$dep} = $depline;
 681                                 }
 682                         }
 683                         my $depline = join(" ", values %deplines);
 684                         if ($depline) {
 685                                 $line .= "\$(curdir)/".$pkg->{subdir}."$pkg->{src}/$type/compile += $depline\n";
 686                         }
 687                 }
 688
 689                 my $hasdeps = 0;
 690                 my %deplines;
 691                 foreach my $deps (@srcdeps) {
 692                         my $idx;
 693                         my $condition;
 694                         my $prefix = "";
 695                         my $suffix = "";
 696
 697                         if ($deps =~ /^(.+):(.+)/) {
 698                                 $condition = $1;
 699                                 $deps = $2;
 700                         }
 701                         if ($deps =~ /^(.+)(\/.+)/) {
 702                                 $deps = $1;
 703                                 $suffix = $2;
 704                         }
 705
 706                         my $pkg_dep = $package{$deps};
 707                         my @deps;
 708
 709                         if ($pkg_dep->{vdepends}) {
 710                                 @deps = @{$pkg_dep->{vdepends}};
 711                         } else {
 712                                 @deps = ($deps);
 713                         }
 714
 715                         foreach my $dep (@deps) {
 716                                 $pkg_dep = $package{$deps};
 717                                 if (defined $pkg_dep->{src}) {
 718                                         ($pkg->{src} ne $pkg_dep->{src}.$suffix) and $idx = $pkg_dep->{subdir}.$pkg_dep->{src};
 719                                 } elsif (defined($srcpackage{$dep})) {
 720                                         $idx = $subdir{$dep}.$dep;
 721                                 }
 722                                 $idx .= $suffix;
 723                                 undef $idx if $idx =~ /^(kernel)|(base-files)$/;
 724                                 if ($idx) {
 725                                         my $depline;
 726                                         next if $pkg->{src} eq $pkg_dep->{src}.$suffix;
 727                                         next if $dep{$pkg->{src}."->".$idx};
 728                                         next if $dep{$pkg->{src}."->($dep)".$idx} and $pkg_dep->{vdepends};
 729                                         my $depstr;
 730
 731                                         if ($pkg_dep->{vdepends}) {
 732                                                 $depstr = "\$(if \$(CONFIG_PACKAGE_$dep),\$(curdir)/$idx/compile)";
 733                                                 $dep{$pkg->{src}."->($dep)".$idx} = 1;
 734                                         } else {
 735                                                 $depstr = "\$(curdir)/$idx/compile";
 736                                                 $dep{$pkg->{src}."->".$idx} = 1;
 737                                         }
 738                                         $depline = get_conditional_dep($condition, $depstr);
 739                                         if ($depline) {
 740                                                 $deplines{$idx.$dep} = $depline;
 741                                         }
 742                                 }
 743                         }
 744                 }
 745                 my $depline = join(" ", values %deplines);
 746                 if ($depline) {
 747                         $line .= "\$(curdir)/".$pkg->{subdir}."$pkg->{src}/compile += $depline\n";
 748                 }
 749         }
 750
 751         if ($line ne "") {
 752                 print "\n$line";
 753         }
 754         foreach my $preconfig (keys %preconfig) {
 755                 my $cmds;
 756                 foreach my $cfg (keys %{$preconfig{$preconfig}}) {
 757                         my $conf = $preconfig{$preconfig}->{$cfg}->{id};
 758                         $conf =~ tr/\.-/__/;
 759                         $cmds .= "\techo \"uci set '$preconfig{$preconfig}->{$cfg}->{id}=\$(subst \",,\$(CONFIG_UCI_PRECONFIG_$conf))'\"; \\\n";
 760                 }
 761                 next unless $cmds;
 762                 print <<EOF
 763
 764 \$(TARGET_DIR)/etc/uci-defaults/$preconfig: FORCE
 765         ( \\
 766 $cmds \\
 767         ) > \$@
 768
 769 ifneq (\$(IMAGEOPT)\$(CONFIG_IMAGEOPT),)
 770   package/preconfig: \$(TARGET_DIR)/etc/uci-defaults/$preconfig
 771 endif
 772 EOF
 773         }
 774 }
 775
 776 sub gen_package_source() {
 777         parse_package_metadata($ARGV[0]) or exit 1;
 778         foreach my $name (sort {uc($a) cmp uc($b)} keys %package) {
 779                 my $pkg = $package{$name};
 780                 if ($pkg->{name} && $pkg->{source}) {
 781                         print "$pkg->{name}: ";
 782                         print "$pkg->{source}\n";
 783                 }
 784         }
 785 }
 786
 787 sub parse_command() {
 788         my $cmd = shift @ARGV;
 789         for ($cmd) {
 790                 /^target_config$/ and return gen_target_config();
 791                 /^package_mk$/ and return gen_package_mk();
 792                 /^package_config$/ and return gen_package_config();
 793                 /^kconfig/ and return gen_kconfig_overrides();
 794                 /^package_source$/ and return gen_package_source();
 795         }
 796         print <<EOF
 797 Available Commands:
 798         $0 target_config [file]         Target metadata in Kconfig format
 799         $0 package_mk [file]            Package metadata in makefile format
 800         $0 package_config [file]        Package metadata in Kconfig format
 801         $0 kconfig [file] [config]      Kernel config overrides
 802         $0 package_source [file]        Package source file information
 803
 804 EOF
 805 }
 806
 807 parse_command();