scripts/feeds

   1 #!/usr/bin/perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13
  14 my $mk=`which gmake`;   # select the right 'make' program
  15 chomp($mk);             # trim trailing newline
  16 $mk or $mk = "make";    # default to 'make'
  17
  18 my @feeds;
  19 my %build_packages;
  20 my %installed;
  21
  22 sub parse_config() {
  23         my $line = 0;
  24         my %name;
  25
  26         open FEEDS, "feeds.conf" or
  27                 open FEEDS, "feeds.conf.default" or
  28                 die "Unable to open feeds configuration";
  29         while (<FEEDS>) {
  30                 chomp;
  31                 s/#.+$//;
  32                 next unless /\S/;
  33                 my @line = split /\s+/, $_, 3;
  34                 my @src;
  35                 $line++;
  36
  37                 my $valid = 1;
  38                 $line[0] =~ /^src-\w+$/ or $valid = 0;
  39                 $line[1] =~ /^\w+$/ or $valid = 0;
  40                 @src = split /\s+/, $line[2];
  41                 $valid or die "Syntax error in feeds.list, line: $line\n";
  42
  43                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  44                 $name{$line[1]} = 1;
  45
  46                 push @feeds, [$line[0], $line[1], \@src];
  47         }
  48         close FEEDS;
  49 }
  50
  51 sub update_index($)
  52 {
  53         my $name = shift;
  54
  55         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  56         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
  57
  58         system("$mk -s prepare-mk TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
  59         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=4 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
  60         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
  61
  62         return 0;
  63 }
  64
  65 sub update_svn($$) {
  66         my $name = shift;
  67         my $src = shift;
  68
  69         if (-d "./feeds/$name/.svn" ) {
  70                 system("(cd \"./feeds/$name\"; svn up)") == 0 or return 1;
  71         } else {
  72                 system("rm -rf \"./feeds/$name\"");
  73                 system("svn co $src \"./feeds/$name\"") == 0 or return 1;
  74         }
  75
  76         return 0;
  77 }
  78
  79 sub update_cpy($$) {
  80         my $name = shift;
  81         my $src = shift;
  82
  83         system("mkdir -p ./feeds/$name");
  84         system("cp -Rf $src ./feeds");
  85
  86         return 0;
  87 }
  88
  89 sub update_link($$) {
  90         my $name = shift;
  91         my $src = abs_path(shift);
  92
  93         system("rm -f ./feeds/$name; ln -s $src ./feeds/$name");
  94
  95         return 0;
  96 }
  97
  98 sub update_git($$) {
  99         my $name = shift;
 100         my $src = shift;
 101
 102         if (-d "./feeds/$name/.git" ) {
 103                 system("GIT_DIR=./feeds/$name/.git git pull") == 0 or return 1;
 104         } else {
 105                 system("rm -rf \"./feeds/$name\"");
 106                 system("git clone --depth 1 $src ./feeds/$name") == 0 or return 1;
 107         }
 108
 109         return 0;
 110 }
 111
 112 sub get_feed($) {
 113         my $feed = shift;
 114         my $file = "./feeds/$feed.index";
 115
 116         clear_packages();
 117
 118         -f $file or do {
 119                 print "Ignoring feed '$feed' - index missing\n";
 120                 return;
 121         };
 122         parse_package_metadata($file) or return;
 123         return { %package };
 124 }
 125
 126 sub get_installed() {
 127         system("$mk -s prepare-tmpinfo");
 128         clear_packages();
 129         parse_package_metadata("./tmp/.packageinfo");
 130         %installed = %package;
 131 }
 132
 133 sub search_feed {
 134         my $feed = shift;
 135         my @substr = @_;
 136         my $display;
 137
 138         return unless @substr > 0;
 139         get_feed($feed);
 140         foreach my $name (sort { lc($a) cmp lc($b) } keys %package) {
 141                 my $pkg = $package{$name};
 142                 my $substr;
 143                 my $pkgmatch = 1;
 144
 145                 foreach my $substr (@substr) {
 146                         my $match;
 147                         foreach my $key (qw(name title description)) {
 148                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 149                         }
 150                         $match or undef $pkgmatch;
 151                 };
 152                 $pkgmatch and do {
 153                         $display or do {
 154                                 print "Search results in feed '$feed':\n";
 155                                 $display = 1;
 156                         };
 157                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 158                 };
 159         }
 160         return 0;
 161 }
 162
 163 sub search {
 164         my %opts;
 165
 166         getopt('r:', \%opts);
 167         foreach my $feed (@feeds) {
 168                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 169         }
 170 }
 171
 172 sub list_feed {
 173         my $feed = shift;
 174
 175         get_feed($feed);
 176         foreach my $name (sort { lc($a) cmp lc($b) } keys %package) {
 177                 my $pkg = $package{$name};
 178                 if($pkg->{name}) {
 179                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 180                 }
 181         }
 182
 183         return 0;
 184 }
 185
 186 sub list {
 187         my %opts;
 188
 189         getopts('r:sh', \%opts);
 190         if ($opts{h}) {
 191                 usage();
 192                 return 0;
 193         }
 194         if ($opts{s}) {
 195                 foreach my $feed (@feeds) {
 196                         printf "\%-32s\tURL: %s\n", $feed->[1], join(", ", @{$feed->[2]});
 197                 }
 198                 return 0;
 199         }
 200         foreach my $feed (@feeds) {
 201                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 202         }
 203         return 0;
 204 }
 205
 206 sub install_generic() {
 207         my $feed = shift;
 208         my $pkg = shift;
 209         my $path = $pkg->{makefile};
 210
 211         if($path) {
 212                 $path =~ s/\/Makefile$//;
 213
 214                 -d "./package/feeds" or mkdir "./package/feeds";
 215                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 216                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 217         } else {
 218                 warn "Package is not valid\n";
 219                 return 1;
 220         }
 221
 222         return 0;
 223 }
 224
 225 my %install_method = (
 226         'src-svn' => \&install_generic,
 227         'src-cpy' => \&install_generic,
 228         'src-link' => \&install_generic,
 229         'src-git' => \&install_generic,
 230 );
 231
 232 my %feed;
 233
 234 sub lookup_package($$) {
 235         my $feed = shift;
 236         my $package = shift;
 237
 238         foreach my $feed ($feed, @feeds) {
 239                 next unless $feed->[1];
 240                 next unless $feed{$feed->[1]};
 241                 $feed{$feed->[1]}->{$package} and return $feed;
 242         }
 243         return;
 244 }
 245
 246 sub install_package {
 247         my $feed = shift;
 248         my $name = shift;
 249         my $ret = 0;
 250
 251         $feed = lookup_package($feed, $name);
 252         $feed or do {
 253                 $installed{$name} and return 0;
 254                 # TODO: check if it's already installed within ./package directory
 255                 $srcpackage{$name} or -d "./package/$name" or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 256                 return 0;
 257         };
 258
 259         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
 260         $pkg->{name} or do {
 261                 $installed{$name} and return 0;
 262                 # TODO: check if this is an alias package, maybe it's known by another name
 263                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 264                 return 0;
 265         };
 266         my $src = $pkg->{src};
 267         my $type = $feed->[0];
 268         $src or $src = $name;
 269
 270         # previously installed packages set the runtime package
 271         # newly installed packages set the source package
 272         $installed{$src} and return 0;
 273
 274         # check previously installed packages
 275         $installed{$name} and return 0;
 276         $installed{$src} = 1;
 277         warn "Installing package '$src'\n";
 278
 279         $install_method{$type} or do {
 280                 warn "Unknown installation method: '$type'\n";
 281                 return 1;
 282         };
 283
 284         &{$install_method{$type}}($feed, $pkg) == 0 or do {
 285                 warn "failed.\n";
 286                 return 1;
 287         };
 288
 289         # install all dependencies
 290         foreach my $vpkg (@{$srcpackage{$src}}, $pkg) {
 291                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}) {
 292                         next if $dep =~ /@/;
 293                         $dep =~ s/^\+//;
 294                         $dep =~ s/^.+://;
 295                         next unless $dep;
 296                         install_package($feed, $dep) == 0 or $ret = 1;
 297                 }
 298         }
 299
 300         return $ret;
 301 }
 302
 303 sub refresh_config {
 304         my $default = shift;
 305
 306         # workaround for timestamp check
 307         system("rm -f tmp/.packageinfo");
 308
 309         # refresh the config
 310         if ($default) {
 311                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 312         } else {
 313                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 314         }
 315 }
 316
 317 sub install {
 318         my $name;
 319         my %opts;
 320         my $feed;
 321         my $ret = 0;
 322
 323         getopts('ap:d:h', \%opts);
 324
 325         if ($opts{h}) {
 326                 usage();
 327                 return 0;
 328         }
 329
 330         get_installed();
 331
 332         foreach my $f (@feeds) {
 333                 # index all feeds
 334                 $feed{$f->[1]} = get_feed($f->[1]);
 335
 336                 # look up the preferred feed
 337                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 338         }
 339
 340         if($opts{a}) {
 341                 foreach my $f (@feeds) {
 342                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 343                                 printf "Installing all packages from feed %s.\n", $f->[1];
 344                                 get_feed($f->[1]);
 345                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %package) {
 346                                         my $p = $package{$name};
 347                                         if( $p->{name} ) {
 348                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
 349                                         }
 350                                 }
 351                         }
 352                 }
 353         } else {
 354                 while ($name = shift @ARGV) {
 355                         install_package($feed, $name) == 0 or $ret = 1;
 356                 }
 357         }
 358
 359         # workaround for timestamp check
 360
 361         # set the defaults
 362         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 363                 refresh_config($opts{d});
 364         }
 365
 366         return $ret;
 367 }
 368
 369 sub uninstall {
 370         my %opts;
 371         my $name;
 372         my $uninstall;
 373
 374         getopts('ah', \%opts);
 375
 376         if ($opts{h}) {
 377                 usage();
 378                 return 0;
 379         }
 380
 381         if ($opts{a}) {
 382                 system("rm -rvf ./package/feeds");
 383                 $uninstall = 1;
 384         } else {
 385                 if($#ARGV == -1) {
 386                         warn "WARNING: no package to uninstall\n";
 387                         return 0;
 388                 }
 389                 get_installed();
 390                 while ($name = shift @ARGV) {
 391                         my $pkg = $installed{$name};
 392                         $pkg or do {
 393                                 warn "WARNING: $name not installed\n";
 394                                 next;
 395                         };
 396                         $pkg->{src} and $name = $pkg->{src};
 397                         warn "Uninstalling package '$name'\n";
 398                         system("rm -f ./package/feeds/*/$name");
 399                         $uninstall = 1;
 400                 }
 401         }
 402         $uninstall and refresh_config();
 403         return 0;
 404 }
 405
 406 my %update_method = (
 407         'src-svn' => \&update_svn,
 408         'src-cpy' => \&update_cpy,
 409         'src-link' => \&update_link,
 410         'src-git' => \&update_git
 411 );
 412
 413 sub update_feed($$$$)
 414 {
 415         my $type=shift;
 416         my $name=shift;
 417         my $src=shift;
 418         my $perform_update=shift;
 419
 420         $update_method{$type} or do {
 421                 warn "Unknown type '$type' in feed $name\n";
 422                 return 1;
 423         };
 424         $perform_update and do {
 425                 my $failed = 1;
 426                 foreach my $feedsrc (@$src) {
 427                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 428                         next unless &{$update_method{$type}}($name, $feedsrc) == 0;
 429                         $failed = 0;
 430                         last;
 431                 }
 432                 $failed and do {
 433                         warn "failed.\n";
 434                         return 1;
 435                 };
 436         };
 437         warn "Create index file './feeds/$name.index' \n";
 438         update_index($name) == 0 or do {
 439                 warn "failed.\n";
 440                 return 1;
 441         };
 442         return 0;
 443 }
 444
 445 sub update {
 446         my %opts;
 447         my $feed_name;
 448         my $perform_update=1;
 449
 450         $ENV{SCAN_COOKIE} = $$;
 451         $ENV{KBUILD_VERBOSE} = 99;
 452
 453         getopts('ahi', \%opts);
 454
 455         if ($opts{h}) {
 456                 usage();
 457                 return 0;
 458         }
 459
 460         if ($opts{i}) {
 461                 # don't update from (remote) repository
 462                 # only re-create index information
 463                 $perform_update=0;
 464         }
 465
 466         -d "feeds" or do {
 467                         mkdir "feeds" or die "Unable to create the feeds directory";
 468                 };
 469
 470         if ( ($#ARGV == -1) or $opts{a}) {
 471                 foreach my $feed (@feeds) {
 472                         my ($type, $name, $src) = @$feed;
 473                         update_feed($type, $name, $src, $perform_update);
 474                 }
 475         } else {
 476                 while ($feed_name = shift @ARGV) {
 477                         foreach my $feed (@feeds) {
 478                                 my ($type, $name, $src) = @$feed;
 479                                 if($feed_name ne $name) {
 480                                         next;
 481                                 }
 482                                 update_feed($type, $name, $src, $perform_update);
 483                         }
 484                 }
 485         }
 486
 487         refresh_config();
 488
 489         return 0;
 490 }
 491
 492 sub usage() {
 493         print <<EOF;
 494 Usage: $0 <command> [options]
 495
 496 Commands:
 497         list [options]: List feeds and their content
 498         Options:
 499             -s :           List of feed names and their URL.
 500             -r <feedname>: List packages of specified feed.
 501
 502         install [options] <package>: Install a package
 503         Options:
 504             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 505             -p <feedname>: Prefer this feed when installing packages.
 506             -d <y|m|n>:    Set default for newly installed packages.
 507
 508         search [options] <substring>: Search for a package
 509         Options:
 510             -r <feedname>: Only search in this feed
 511
 512         uninstall -a|<package>: Uninstall a package
 513         Options:
 514             -a :           Uninstalls all packages.
 515
 516         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 517         Options:
 518             -a :           Update all feeds listed within feeds.conf. Otherwise the spezified feeds will be updated.
 519             -i :           Recreate the index only. No feed update from repository is performed.
 520
 521         clean:             Remove downloaded/generated files.
 522
 523 EOF
 524         exit(1);
 525 }
 526
 527 my %commands = (
 528         'list' => \&list,
 529         'update' => \&update,
 530         'install' => \&install,
 531         'search' => \&search,
 532         'uninstall' => \&uninstall,
 533         'clean' => sub {
 534                 system("rm -rf feeds");
 535         }
 536 );
 537
 538 my $arg = shift @ARGV;
 539 $arg or usage();
 540 parse_config;
 541 foreach my $cmd (keys %commands) {
 542         $arg eq $cmd and do {
 543                 exit(&{$commands{$cmd}}());
 544         };
 545 }
 546 usage();