scripts/feeds

   1 #!/usr/bin/perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  14 $ENV{GREP_OPTIONS}="";
  15
  16 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  17 chomp($mk);             # trim trailing newline
  18 $mk or $mk = "make";    # default to 'make'
  19
  20 # check version of make
  21 my @mkver = split /\s+/, `$mk -v`, 4;
  22 my $valid_mk = 1;
  23 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  24 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  25 $mkver[2] >= "3.81" or $valid_mk = 0;
  26 $valid_mk or die "Unsupported version of make found: $mk\n";
  27
  28 my @feeds;
  29 my %build_packages;
  30 my %installed;
  31 my %feed_cache;
  32
  33 my $feed_package = {};
  34 my $feed_src = {};
  35
  36 sub parse_config() {
  37         my $line = 0;
  38         my %name;
  39
  40         open FEEDS, "feeds.conf" or
  41                 open FEEDS, "feeds.conf.default" or
  42                 die "Unable to open feeds configuration";
  43         while (<FEEDS>) {
  44                 chomp;
  45                 s/#.+$//;
  46                 next unless /\S/;
  47                 my @line = split /\s+/, $_, 3;
  48                 my @src;
  49                 $line++;
  50
  51                 my $valid = 1;
  52                 $line[0] =~ /^src-[\w-]+$/ or $valid = 0;
  53                 $line[1] =~ /^\w+$/ or $valid = 0;
  54                 @src = split /\s+/, $line[2];
  55                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  56
  57                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  58                 $name{$line[1]} = 1;
  59
  60                 push @feeds, [$line[0], $line[1], \@src];
  61         }
  62         close FEEDS;
  63 }
  64
  65 sub update_location($$)
  66 {
  67         my $name = shift;
  68         my $url  = shift;
  69         my $old_url;
  70
  71         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  72
  73         if( open LOC, "< ./feeds/$name.tmp/location" )
  74         {
  75                 chomp($old_url = readline LOC);
  76                 close LOC;
  77         }
  78
  79         if( !$old_url || $old_url ne $url )
  80         {
  81                 if( open LOC, "> ./feeds/$name.tmp/location" )
  82                 {
  83                         print LOC $url, "\n";
  84                         close LOC;
  85                 }
  86                 return $old_url ? 1 : 0;
  87         }
  88
  89         return 0;
  90 }
  91
  92 sub update_index($)
  93 {
  94         my $name = shift;
  95
  96         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  97         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
  98
  99         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 100         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 101         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 102
 103         return 0;
 104 }
 105
 106 my %update_method = (
 107         'src-svn' => {
 108                 'init'          => "svn checkout '%s' '%s'",
 109                 'update'        => "svn update",
 110                 'controldir'    => ".svn",
 111                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 112         'src-cpy' => {
 113                 'init'          => "cp -Rf '%s' '%s'",
 114                 'update'        => "",
 115                 'revision'      => "echo -n 'local'"},
 116         'src-link' => {
 117                 'init'          => "ln -s '%s' '%s'",
 118                 'update'        => "",
 119                 'revision'      => "echo -n 'local'"},
 120         'src-git' => {
 121                 'init'          => "git clone --depth 1 '%s' '%s'",
 122                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 123                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 124                 'update'        => "git pull --ff",
 125                 'controldir'    => ".git",
 126                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 127         'src-git-full' => {
 128                 'init'          => "git clone '%s' '%s'",
 129                 'init_branch'   => "git clone --branch '%s' '%s' '%s'",
 130                 'init_commit'   => "git clone '%s' '%s' && cd '%s' && git checkout -b '%s' '%s' && cd -",
 131                 'update'        => "git pull --ff",
 132                 'controldir'    => ".git",
 133                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 134         'src-gitsvn' => {
 135                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 136                 'update'        => "git svn rebase",
 137                 'controldir'    => ".git",
 138                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 139         'src-bzr' => {
 140                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 141                 'update'        => "bzr update",
 142                 'controldir'    => ".bzr"},
 143         'src-hg' => {
 144                 'init'          => "hg clone '%s' '%s'",
 145                 'update'        => "hg pull --update",
 146                 'controldir'    => ".hg"},
 147         'src-darcs' => {
 148                 'init'    => "darcs get '%s' '%s'",
 149                 'update'  => "darcs pull -a",
 150                 'controldir' => "_darcs"},
 151 );
 152
 153 # src-git: pull broken
 154 # src-cpy: broken if `basename $src` != $name
 155
 156 sub update_feed_via($$$$) {
 157         my $type = shift;
 158         my $name = shift;
 159         my $src = shift;
 160         my $relocate = shift;
 161
 162         my $m = $update_method{$type};
 163         my $localpath = "./feeds/$name";
 164         my $safepath = $localpath;
 165         $safepath =~ s/'/'\\''/;
 166         my ($base_branch, $branch) = split(/;/, $src, 2);
 167         my ($base_commit, $commit) = split(/\^/, $src, 2);
 168
 169         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 170                 system("rm -rf '$safepath'");
 171                 if ($m->{'init_branch'} and $branch) {
 172                         system(sprintf($m->{'init_branch'}, $branch, $base_branch, $safepath)) == 0 or return 1;
 173                 } elsif ($m->{'init_commit'} and $commit) {
 174                         system(sprintf($m->{'init_commit'}, $base_commit, $safepath, $safepath, $commit, $commit)) == 0 or return 1;
 175                 } else {
 176                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 177                 }
 178         } elsif ($m->{'init_commit'} and $commit) {
 179                 # in case git hash has been provided don't update the feed
 180         } else {
 181                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
 182         }
 183
 184         return 0;
 185 }
 186
 187 sub get_feed($) {
 188         my $feed = shift;
 189
 190         if (!defined($feed_cache{$feed})) {
 191                 my $file = "./feeds/$feed.index";
 192
 193                 clear_packages();
 194                 -f $file or do {
 195                         print "Ignoring feed '$feed' - index missing\n";
 196                         return;
 197                 };
 198                 parse_package_metadata($file) or return;
 199                 $feed_cache{$feed} = [ { %package }, { %srcpackage } ];
 200         }
 201
 202         $feed_package = $feed_cache{$feed}->[0];
 203         $feed_src = $feed_cache{$feed}->[1];
 204         return $feed_cache{$feed}->[0];
 205 }
 206
 207 sub get_installed() {
 208         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 209         clear_packages();
 210         parse_package_metadata("./tmp/.packageinfo");
 211         %installed = %package;
 212 }
 213
 214 sub search_feed {
 215         my $feed = shift;
 216         my @substr = @_;
 217         my $display;
 218
 219         return unless @substr > 0;
 220         get_feed($feed);
 221         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 222                 my $pkg = $feed_package->{$name};
 223                 my $substr;
 224                 my $pkgmatch = 1;
 225
 226                 next if $pkg->{vdepends};
 227                 foreach my $substr (@substr) {
 228                         my $match;
 229                         foreach my $key (qw(name title description src)) {
 230                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 231                         }
 232                         $match or undef $pkgmatch;
 233                 };
 234                 $pkgmatch and do {
 235                         $display or do {
 236                                 print "Search results in feed '$feed':\n";
 237                                 $display = 1;
 238                         };
 239                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 240                 };
 241         }
 242         return 0;
 243 }
 244
 245 sub search {
 246         my %opts;
 247
 248         getopt('r:', \%opts);
 249         foreach my $feed (@feeds) {
 250                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 251         }
 252 }
 253
 254 sub list_feed {
 255         my $feed = shift;
 256
 257         get_feed($feed);
 258         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 259                 my $pkg = $feed_package->{$name};
 260                 next if $pkg->{vdepends};
 261                 if($pkg->{name}) {
 262                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 263                 }
 264         }
 265
 266         return 0;
 267 }
 268
 269 sub list {
 270         my %opts;
 271
 272         getopts('r:d:nsh', \%opts);
 273         if ($opts{h}) {
 274                 usage();
 275                 return 0;
 276         }
 277         if ($opts{n}) {
 278                 foreach my $feed (@feeds) {
 279                         printf "%s\n", $feed->[1];
 280                 }
 281                 return 0;
 282         }
 283         if ($opts{s}) {
 284                 foreach my $feed (@feeds) {
 285                         my $localpath = "./feeds/$feed->[1]";
 286                         my $m = $update_method{$feed->[0]};
 287                         my $revision;
 288                         if( !$m->{'revision'} ) {
 289                                 $revision = "X";
 290                         }
 291                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 292                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 293                         }
 294                         else {
 295                                 $revision = "local";
 296                         }
 297                         if ($opts{d}) {
 298                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 299                         }
 300                         else {
 301                                 printf "\%-8s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 302                         }
 303                 }
 304                 return 0;
 305         }
 306         foreach my $feed (@feeds) {
 307                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 308         }
 309         return 0;
 310 }
 311
 312 sub install_generic() {
 313         my $feed = shift;
 314         my $pkg = shift;
 315         my $path = $pkg->{makefile};
 316
 317         if($path) {
 318                 $path =~ s/\/Makefile$//;
 319
 320                 -d "./package/feeds" or mkdir "./package/feeds";
 321                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 322                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 323         } else {
 324                 warn "Package is not valid\n";
 325                 return 1;
 326         }
 327
 328         return 0;
 329 }
 330
 331 my %install_method = (
 332         'src-svn' => \&install_generic,
 333         'src-cpy' => \&install_generic,
 334         'src-link' => \&install_generic,
 335         'src-git' => \&install_generic,
 336         'src-gitsvn' => \&install_generic,
 337         'src-bzr' => \&install_generic,
 338         'src-hg' => \&install_generic,
 339         'src-darcs' => \&install_generic,
 340 );
 341
 342 my %feed;
 343
 344 sub lookup_package($$) {
 345         my $feed = shift;
 346         my $package = shift;
 347
 348         foreach my $feed ($feed, @feeds) {
 349                 next unless $feed->[1];
 350                 next unless $feed{$feed->[1]};
 351                 $feed{$feed->[1]}->{$package} and return $feed;
 352         }
 353         return;
 354 }
 355
 356 sub is_core_package($) {
 357         my $package = shift;
 358         foreach my $file ("tmp/info/.packageinfo-$package", glob("tmp/info/.packageinfo-*_$package")) {
 359                 next unless index($file, "tmp/info/.packageinfo-feeds_");
 360                 return 1 if -s $file;
 361         }
 362         return 0;
 363 }
 364
 365 sub install_package {
 366         my $feed = shift;
 367         my $name = shift;
 368         my $ret = 0;
 369
 370         $feed = lookup_package($feed, $name);
 371         $feed or do {
 372                 $installed{$name} and return 0;
 373                 # TODO: check if it's already installed within ./package directory
 374                 $feed_src->{$name} or is_core_package($name) or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 375                 return 0;
 376         };
 377
 378         # switch to the metadata for the selected feed
 379         get_feed($feed->[1]);
 380
 381         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
 382         $pkg->{name} or do {
 383                 $installed{$name} and return 0;
 384                 # TODO: check if this is an alias package, maybe it's known by another name
 385                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 386                 return 0;
 387         };
 388         my $src = $pkg->{src};
 389         my $type = $feed->[0];
 390         $src or $src = $name;
 391
 392         # previously installed packages set the runtime package
 393         # newly installed packages set the source package
 394         $installed{$src} and return 0;
 395
 396         # check previously installed packages
 397         $installed{$name} and return 0;
 398         $installed{$src} = 1;
 399         warn "Installing package '$src'\n";
 400
 401         $install_method{$type} or do {
 402                 warn "Unknown installation method: '$type'\n";
 403                 return 1;
 404         };
 405
 406         &{$install_method{$type}}($feed, $pkg) == 0 or do {
 407                 warn "failed.\n";
 408                 return 1;
 409         };
 410
 411         # install all dependencies referenced from the source package
 412         foreach my $vpkg (@{$feed_src->{$src}}) {
 413                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 414                         next if $dep =~ /@/;
 415                         $dep =~ s/^\+//;
 416                         $dep =~ s/^.+://;
 417                         $dep =~ s/\/.+$//;
 418                         next unless $dep;
 419                         install_package($feed, $dep) == 0 or $ret = 1;
 420                 }
 421         }
 422
 423         return $ret;
 424 }
 425
 426 sub refresh_config {
 427         my $default = shift;
 428
 429         # workaround for timestamp check
 430         system("rm -f tmp/.packageinfo");
 431
 432         # refresh the config
 433         if ($default) {
 434                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 435         } else {
 436                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 437         }
 438 }
 439
 440 sub install {
 441         my $name;
 442         my %opts;
 443         my $feed;
 444         my $ret = 0;
 445
 446         getopts('ap:d:h', \%opts);
 447
 448         if ($opts{h}) {
 449                 usage();
 450                 return 0;
 451         }
 452
 453         get_installed();
 454
 455         foreach my $f (@feeds) {
 456                 # index all feeds
 457                 $feed{$f->[1]} = get_feed($f->[1]);
 458
 459                 # look up the preferred feed
 460                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 461         }
 462
 463         if($opts{a}) {
 464                 foreach my $f (@feeds) {
 465                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 466                                 printf "Installing all packages from feed %s.\n", $f->[1];
 467                                 get_feed($f->[1]);
 468                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 469                                         my $p = $feed_package->{$name};
 470                                         next if $p->{vdepends};
 471                                         if( $p->{name} ) {
 472                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
 473                                                 get_feed($f->[1]);
 474                                         }
 475                                 }
 476                         }
 477                 }
 478         } else {
 479                 while ($name = shift @ARGV) {
 480                         install_package($feed, $name) == 0 or $ret = 1;
 481                 }
 482         }
 483
 484         # workaround for timestamp check
 485
 486         # set the defaults
 487         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 488                 refresh_config($opts{d});
 489         }
 490
 491         return $ret;
 492 }
 493
 494 sub uninstall {
 495         my %opts;
 496         my $name;
 497         my $uninstall;
 498
 499         getopts('ah', \%opts);
 500
 501         if ($opts{h}) {
 502                 usage();
 503                 return 0;
 504         }
 505
 506         if ($opts{a}) {
 507                 system("rm -rvf ./package/feeds");
 508                 $uninstall = 1;
 509         } else {
 510                 if($#ARGV == -1) {
 511                         warn "WARNING: no package to uninstall\n";
 512                         return 0;
 513                 }
 514                 get_installed();
 515                 while ($name = shift @ARGV) {
 516                         my $pkg = $installed{$name};
 517                         $pkg or do {
 518                                 warn "WARNING: $name not installed\n";
 519                                 next;
 520                         };
 521                         $pkg->{src} and $name = $pkg->{src};
 522                         warn "Uninstalling package '$name'\n";
 523                         system("rm -f ./package/feeds/*/$name");
 524                         $uninstall = 1;
 525                 }
 526         }
 527         $uninstall and refresh_config();
 528         return 0;
 529 }
 530
 531 sub update_feed($$$$)
 532 {
 533         my $type=shift;
 534         my $name=shift;
 535         my $src=shift;
 536         my $perform_update=shift;
 537         my $force_relocate=update_location( $name, "@$src" );
 538
 539         if( $force_relocate ) {
 540                 warn "Source of feed $name has changed, replacing copy\n";
 541         }
 542         $update_method{$type} or do {
 543                 warn "Unknown type '$type' in feed $name\n";
 544                 return 1;
 545         };
 546         $perform_update and do {
 547                 my $failed = 1;
 548                 foreach my $feedsrc (@$src) {
 549                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 550                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
 551                         $failed = 0;
 552                         last;
 553                 }
 554                 $failed and do {
 555                         warn "failed.\n";
 556                         return 1;
 557                 };
 558         };
 559         warn "Create index file './feeds/$name.index' \n";
 560         update_index($name) == 0 or do {
 561                 warn "failed.\n";
 562                 return 1;
 563         };
 564         return 0;
 565 }
 566
 567 sub update {
 568         my %opts;
 569         my $feed_name;
 570         my $perform_update=1;
 571
 572         $ENV{SCAN_COOKIE} = $$;
 573         $ENV{OPENWRT_VERBOSE} = 's';
 574
 575         getopts('ahi', \%opts);
 576
 577         if ($opts{h}) {
 578                 usage();
 579                 return 0;
 580         }
 581
 582         if ($opts{i}) {
 583                 # don't update from (remote) repository
 584                 # only re-create index information
 585                 $perform_update=0;
 586         }
 587
 588         -d "feeds" or do {
 589                         mkdir "feeds" or die "Unable to create the feeds directory";
 590                 };
 591
 592         if ( ($#ARGV == -1) or $opts{a}) {
 593                 foreach my $feed (@feeds) {
 594                         my ($type, $name, $src) = @$feed;
 595                         update_feed($type, $name, $src, $perform_update);
 596                 }
 597         } else {
 598                 while ($feed_name = shift @ARGV) {
 599                         foreach my $feed (@feeds) {
 600                                 my ($type, $name, $src) = @$feed;
 601                                 if($feed_name ne $name) {
 602                                         next;
 603                                 }
 604                                 update_feed($type, $name, $src, $perform_update);
 605                         }
 606                 }
 607         }
 608
 609         refresh_config();
 610
 611         return 0;
 612 }
 613
 614 sub feed_config() {
 615         foreach my $feed (@feeds) {
 616                 my $installed = (-f "feeds/$feed->[1].index");
 617
 618                 printf "\tconfig FEED_%s\n", $feed->[1];
 619                 printf "\t\tbool \"Enable feed %s\"\n", $feed->[1];
 620                 printf "\t\tdepends on PER_FEED_REPO\n";
 621                 printf "\t\tdefault y\n" if $installed;
 622                 printf "\t\thelp\n";
 623                 printf "\t\t Enable the \\\"%s\\\" feed at %s.\n", $feed->[1], $feed->[2][0];
 624                 printf "\n";
 625         }
 626
 627         return 0;
 628 }
 629
 630 sub usage() {
 631         print <<EOF;
 632 Usage: $0 <command> [options]
 633
 634 Commands:
 635         list [options]: List feeds, their content and revisions (if installed)
 636         Options:
 637             -n :            List of feed names.
 638             -s :            List of feed names and their URL.
 639             -r <feedname>:  List packages of specified feed.
 640             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 641
 642         install [options] <package>: Install a package
 643         Options:
 644             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 645             -p <feedname>: Prefer this feed when installing packages.
 646             -d <y|m|n>:    Set default for newly installed packages.
 647
 648         search [options] <substring>: Search for a package
 649         Options:
 650             -r <feedname>: Only search in this feed
 651
 652         uninstall -a|<package>: Uninstall a package
 653         Options:
 654             -a :           Uninstalls all packages.
 655
 656         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 657         Options:
 658             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 659             -i :           Recreate the index only. No feed update from repository is performed.
 660
 661         clean:             Remove downloaded/generated files.
 662
 663 EOF
 664         exit(1);
 665 }
 666
 667 my %commands = (
 668         'list' => \&list,
 669         'update' => \&update,
 670         'install' => \&install,
 671         'search' => \&search,
 672         'uninstall' => \&uninstall,
 673         'feed_config' => \&feed_config,
 674         'clean' => sub {
 675                 system("rm -rf feeds");
 676         }
 677 );
 678
 679 my $arg = shift @ARGV;
 680 $arg or usage();
 681 parse_config;
 682 foreach my $cmd (keys %commands) {
 683         $arg eq $cmd and do {
 684                 exit(&{$commands{$cmd}}());
 685         };
 686 }
 687 usage();