scripts/feeds

   1 #!/usr/bin/perl
   2 use Getopt::Std;
   3 use FindBin;
   4 use Cwd;
   5 use lib "$FindBin::Bin";
   6 use metadata;
   7 use warnings;
   8 use strict;
   9 use Cwd 'abs_path';
  10
  11 chdir "$FindBin::Bin/..";
  12 $ENV{TOPDIR}=getcwd();
  13 $ENV{GIT_CONFIG_PARAMETERS}="'core.autocrlf=false'";
  14 $ENV{GREP_OPTIONS}="";
  15
  16 my $mk=`which gmake 2>/dev/null`;       # select the right 'make' program
  17 chomp($mk);             # trim trailing newline
  18 $mk or $mk = "make";    # default to 'make'
  19
  20 # check version of make
  21 my @mkver = split /\s+/, `$mk -v`, 4;
  22 my $valid_mk = 1;
  23 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
  24 $mkver[1] =~ /^Make/ or $valid_mk = 0;
  25 $mkver[2] >= "3.81" or $valid_mk = 0;
  26 $valid_mk or die "Unsupported version of make found: $mk\n";
  27
  28 my @feeds;
  29 my %build_packages;
  30 my %installed;
  31 my %feed_cache;
  32
  33 my $feed_package = {};
  34 my $feed_src = {};
  35
  36 sub parse_config() {
  37         my $line = 0;
  38         my %name;
  39
  40         open FEEDS, "feeds.conf" or
  41                 open FEEDS, "feeds.conf.default" or
  42                 die "Unable to open feeds configuration";
  43         while (<FEEDS>) {
  44                 chomp;
  45                 s/#.+$//;
  46                 next unless /\S/;
  47                 my @line = split /\s+/, $_, 3;
  48                 my @src;
  49                 $line++;
  50
  51                 my $valid = 1;
  52                 $line[0] =~ /^src-\w+$/ or $valid = 0;
  53                 $line[1] =~ /^\w+$/ or $valid = 0;
  54                 @src = split /\s+/, $line[2];
  55                 $valid or die "Syntax error in feeds.conf, line: $line\n";
  56
  57                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
  58                 $name{$line[1]} = 1;
  59
  60                 push @feeds, [$line[0], $line[1], \@src];
  61         }
  62         close FEEDS;
  63 }
  64
  65 sub update_location($$)
  66 {
  67         my $name = shift;
  68         my $url  = shift;
  69         my $old_url;
  70
  71         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  72
  73         if( open LOC, "< ./feeds/$name.tmp/location" )
  74         {
  75                 chomp($old_url = readline LOC);
  76                 close LOC;
  77         }
  78
  79         if( !$old_url || $old_url ne $url )
  80         {
  81                 if( open LOC, "> ./feeds/$name.tmp/location" )
  82                 {
  83                         print LOC $url, "\n";
  84                         close LOC;
  85                 }
  86                 return $old_url ? 1 : 0;
  87         }
  88
  89         return 0;
  90 }
  91
  92 sub update_index($)
  93 {
  94         my $name = shift;
  95
  96         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
  97         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
  98
  99         system("$mk -s prepare-mk OPENWRT_BUILD= TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 100         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
 101         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
 102
 103         return 0;
 104 }
 105
 106 my %update_method = (
 107         'src-svn' => {
 108                 'init'          => "svn checkout '%s' '%s'",
 109                 'update'        => "svn update",
 110                 'controldir'    => ".svn",
 111                 'revision'      => "svn info | grep 'Revision' | cut -d ' ' -f 2 | tr -d '\n'"},
 112         'src-cpy' => {
 113                 'init'          => "cp -Rf '%s' '%s'",
 114                 'update'        => "",
 115                 'revision'      => "echo -n 'local'"},
 116         'src-link' => {
 117                 'init'          => "ln -s '%s' '%s'",
 118                 'update'        => "",
 119                 'revision'      => "echo -n 'local'"},
 120         'src-git' => {
 121                 'init'          => "git clone --depth 1 '%s' '%s'",
 122                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
 123                 'update'        => "git pull",
 124                 'controldir'    => ".git",
 125                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 126         'src-gitsvn' => {
 127                 'init'  => "git svn clone -r HEAD '%s' '%s'",
 128                 'update'        => "git svn rebase",
 129                 'controldir'    => ".git",
 130                 'revision'      => "git show --abbrev-commit HEAD | head -n 1 | cut -d ' ' -f 2 | tr -d '\n'"},
 131         'src-bzr' => {
 132                 'init'          => "bzr checkout --lightweight '%s' '%s'",
 133                 'update'        => "bzr update",
 134                 'controldir'    => ".bzr"},
 135         'src-hg' => {
 136                 'init'          => "hg clone '%s' '%s'",
 137                 'update'        => "hg pull --update",
 138                 'controldir'    => ".hg"},
 139         'src-darcs' => {
 140                 'init'    => "darcs get '%s' '%s'",
 141                 'update'  => "darcs pull -a",
 142                 'controldir' => "_darcs"},
 143 );
 144
 145 # src-git: pull broken
 146 # src-cpy: broken if `basename $src` != $name
 147
 148 sub update_feed_via($$$$) {
 149         my $type = shift;
 150         my $name = shift;
 151         my $src = shift;
 152         my $relocate = shift;
 153
 154         my $m = $update_method{$type};
 155         my $localpath = "./feeds/$name";
 156         my $safepath = $localpath;
 157         $safepath =~ s/'/'\\''/;
 158         my ($base, $branch) = split(/;/, $src, 2);
 159
 160         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
 161                 system("rm -rf '$safepath'");
 162                 if ($m->{'init_branch'} and $branch) {
 163                         system(sprintf($m->{'init_branch'}, $branch, $base, $safepath)) == 0 or return 1;
 164                 } else {
 165                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
 166                 }
 167         } else {
 168                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
 169         }
 170
 171         return 0;
 172 }
 173
 174 sub get_feed($) {
 175         my $feed = shift;
 176
 177         if (!defined($feed_cache{$feed})) {
 178                 my $file = "./feeds/$feed.index";
 179
 180                 clear_packages();
 181                 -f $file or do {
 182                         print "Ignoring feed '$feed' - index missing\n";
 183                         return;
 184                 };
 185                 parse_package_metadata($file) or return;
 186                 $feed_cache{$feed} = [ { %package }, { %srcpackage } ];
 187         }
 188
 189         $feed_package = $feed_cache{$feed}->[0];
 190         $feed_src = $feed_cache{$feed}->[1];
 191         return $feed_cache{$feed}->[0];
 192 }
 193
 194 sub get_installed() {
 195         system("$mk -s prepare-tmpinfo OPENWRT_BUILD=");
 196         clear_packages();
 197         parse_package_metadata("./tmp/.packageinfo");
 198         %installed = %package;
 199 }
 200
 201 sub search_feed {
 202         my $feed = shift;
 203         my @substr = @_;
 204         my $display;
 205
 206         return unless @substr > 0;
 207         get_feed($feed);
 208         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 209                 my $pkg = $feed_package->{$name};
 210                 my $substr;
 211                 my $pkgmatch = 1;
 212
 213                 next if $pkg->{vdepends};
 214                 foreach my $substr (@substr) {
 215                         my $match;
 216                         foreach my $key (qw(name title description src)) {
 217                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
 218                         }
 219                         $match or undef $pkgmatch;
 220                 };
 221                 $pkgmatch and do {
 222                         $display or do {
 223                                 print "Search results in feed '$feed':\n";
 224                                 $display = 1;
 225                         };
 226                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
 227                 };
 228         }
 229         return 0;
 230 }
 231
 232 sub search {
 233         my %opts;
 234
 235         getopt('r:', \%opts);
 236         foreach my $feed (@feeds) {
 237                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 238         }
 239 }
 240
 241 sub list_feed {
 242         my $feed = shift;
 243
 244         get_feed($feed);
 245         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 246                 my $pkg = $feed_package->{$name};
 247                 next if $pkg->{vdepends};
 248                 if($pkg->{name}) {
 249                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
 250                 }
 251         }
 252
 253         return 0;
 254 }
 255
 256 sub list {
 257         my %opts;
 258
 259         getopts('r:d:sh', \%opts);
 260         if ($opts{h}) {
 261                 usage();
 262                 return 0;
 263         }
 264         if ($opts{s}) {
 265                 foreach my $feed (@feeds) {
 266                         my $localpath = "./feeds/$feed->[1]";
 267                         my $m = $update_method{$feed->[0]};
 268                         my $revision;
 269                         if( !$m->{'revision'} ) {
 270                                 $revision = "X";
 271                         }
 272                         elsif( $m->{'controldir'} && -d "$localpath/$m->{'controldir'}" ) {
 273                                 $revision = `cd '$localpath'; $m->{'revision'}`;
 274                         }
 275                         else {
 276                                 $revision = "local";
 277                         }
 278                         if ($opts{d}) {
 279                                 printf "%s%s%s%s%s%s%s\n", $feed->[1], $opts{d}, $feed->[0], $opts{d}, $revision, $opts{d}, join(", ", @{$feed->[2]});
 280                         }
 281                         else {
 282                                 printf "\%-8s \%-8s \%-8s \%s\n", $feed->[1], $feed->[0], $revision, join(", ", @{$feed->[2]});
 283                         }
 284                 }
 285                 return 0;
 286         }
 287         foreach my $feed (@feeds) {
 288                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
 289         }
 290         return 0;
 291 }
 292
 293 sub install_generic() {
 294         my $feed = shift;
 295         my $pkg = shift;
 296         my $path = $pkg->{makefile};
 297
 298         if($path) {
 299                 $path =~ s/\/Makefile$//;
 300
 301                 -d "./package/feeds" or mkdir "./package/feeds";
 302                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
 303                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
 304         } else {
 305                 warn "Package is not valid\n";
 306                 return 1;
 307         }
 308
 309         return 0;
 310 }
 311
 312 my %install_method = (
 313         'src-svn' => \&install_generic,
 314         'src-cpy' => \&install_generic,
 315         'src-link' => \&install_generic,
 316         'src-git' => \&install_generic,
 317         'src-gitsvn' => \&install_generic,
 318         'src-bzr' => \&install_generic,
 319         'src-hg' => \&install_generic,
 320         'src-darcs' => \&install_generic,
 321 );
 322
 323 my %feed;
 324
 325 sub lookup_package($$) {
 326         my $feed = shift;
 327         my $package = shift;
 328
 329         foreach my $feed ($feed, @feeds) {
 330                 next unless $feed->[1];
 331                 next unless $feed{$feed->[1]};
 332                 $feed{$feed->[1]}->{$package} and return $feed;
 333         }
 334         return;
 335 }
 336
 337 sub install_package {
 338         my $feed = shift;
 339         my $name = shift;
 340         my $ret = 0;
 341
 342         $feed = lookup_package($feed, $name);
 343         $feed or do {
 344                 $installed{$name} and return 0;
 345                 # TODO: check if it's already installed within ./package directory
 346                 $feed_src->{$name} or -d "./package/$name" or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
 347                 return 0;
 348         };
 349
 350         # switch to the metadata for the selected feed
 351         get_feed($feed->[1]);
 352
 353         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
 354         $pkg->{name} or do {
 355                 $installed{$name} and return 0;
 356                 # TODO: check if this is an alias package, maybe it's known by another name
 357                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
 358                 return 0;
 359         };
 360         my $src = $pkg->{src};
 361         my $type = $feed->[0];
 362         $src or $src = $name;
 363
 364         # previously installed packages set the runtime package
 365         # newly installed packages set the source package
 366         $installed{$src} and return 0;
 367
 368         # check previously installed packages
 369         $installed{$name} and return 0;
 370         $installed{$src} = 1;
 371         warn "Installing package '$src'\n";
 372
 373         $install_method{$type} or do {
 374                 warn "Unknown installation method: '$type'\n";
 375                 return 1;
 376         };
 377
 378         &{$install_method{$type}}($feed, $pkg) == 0 or do {
 379                 warn "failed.\n";
 380                 return 1;
 381         };
 382
 383         # install all dependencies referenced from the source package
 384         foreach my $vpkg (@{$feed_src->{$src}}) {
 385                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
 386                         next if $dep =~ /@/;
 387                         $dep =~ s/^\+//;
 388                         $dep =~ s/^.+://;
 389                         $dep =~ s/\/.+$//;
 390                         next unless $dep;
 391                         install_package($feed, $dep) == 0 or $ret = 1;
 392                 }
 393         }
 394
 395         return $ret;
 396 }
 397
 398 sub refresh_config {
 399         my $default = shift;
 400
 401         # workaround for timestamp check
 402         system("rm -f tmp/.packageinfo");
 403
 404         # refresh the config
 405         if ($default) {
 406                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
 407         } else {
 408                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
 409         }
 410 }
 411
 412 sub install {
 413         my $name;
 414         my %opts;
 415         my $feed;
 416         my $ret = 0;
 417
 418         getopts('ap:d:h', \%opts);
 419
 420         if ($opts{h}) {
 421                 usage();
 422                 return 0;
 423         }
 424
 425         get_installed();
 426
 427         foreach my $f (@feeds) {
 428                 # index all feeds
 429                 $feed{$f->[1]} = get_feed($f->[1]);
 430
 431                 # look up the preferred feed
 432                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
 433         }
 434
 435         if($opts{a}) {
 436                 foreach my $f (@feeds) {
 437                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
 438                                 printf "Installing all packages from feed %s.\n", $f->[1];
 439                                 get_feed($f->[1]);
 440                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
 441                                         my $p = $feed_package->{$name};
 442                                         next if $p->{vdepends};
 443                                         if( $p->{name} ) {
 444                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
 445                                                 get_feed($f->[1]);
 446                                         }
 447                                 }
 448                         }
 449                 }
 450         } else {
 451                 while ($name = shift @ARGV) {
 452                         install_package($feed, $name) == 0 or $ret = 1;
 453                 }
 454         }
 455
 456         # workaround for timestamp check
 457
 458         # set the defaults
 459         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
 460                 refresh_config($opts{d});
 461         }
 462
 463         return $ret;
 464 }
 465
 466 sub uninstall {
 467         my %opts;
 468         my $name;
 469         my $uninstall;
 470
 471         getopts('ah', \%opts);
 472
 473         if ($opts{h}) {
 474                 usage();
 475                 return 0;
 476         }
 477
 478         if ($opts{a}) {
 479                 system("rm -rvf ./package/feeds");
 480                 $uninstall = 1;
 481         } else {
 482                 if($#ARGV == -1) {
 483                         warn "WARNING: no package to uninstall\n";
 484                         return 0;
 485                 }
 486                 get_installed();
 487                 while ($name = shift @ARGV) {
 488                         my $pkg = $installed{$name};
 489                         $pkg or do {
 490                                 warn "WARNING: $name not installed\n";
 491                                 next;
 492                         };
 493                         $pkg->{src} and $name = $pkg->{src};
 494                         warn "Uninstalling package '$name'\n";
 495                         system("rm -f ./package/feeds/*/$name");
 496                         $uninstall = 1;
 497                 }
 498         }
 499         $uninstall and refresh_config();
 500         return 0;
 501 }
 502
 503 sub update_feed($$$$)
 504 {
 505         my $type=shift;
 506         my $name=shift;
 507         my $src=shift;
 508         my $perform_update=shift;
 509         my $force_relocate=update_location( $name, "@$src" );
 510
 511         if( $force_relocate ) {
 512                 warn "Source of feed $name has changed, replacing copy\n";
 513         }
 514         $update_method{$type} or do {
 515                 warn "Unknown type '$type' in feed $name\n";
 516                 return 1;
 517         };
 518         $perform_update and do {
 519                 my $failed = 1;
 520                 foreach my $feedsrc (@$src) {
 521                         warn "Updating feed '$name' from '$feedsrc' ...\n";
 522                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
 523                         $failed = 0;
 524                         last;
 525                 }
 526                 $failed and do {
 527                         warn "failed.\n";
 528                         return 1;
 529                 };
 530         };
 531         warn "Create index file './feeds/$name.index' \n";
 532         update_index($name) == 0 or do {
 533                 warn "failed.\n";
 534                 return 1;
 535         };
 536         return 0;
 537 }
 538
 539 sub update {
 540         my %opts;
 541         my $feed_name;
 542         my $perform_update=1;
 543
 544         $ENV{SCAN_COOKIE} = $$;
 545         $ENV{OPENWRT_VERBOSE} = 's';
 546
 547         getopts('ahi', \%opts);
 548
 549         if ($opts{h}) {
 550                 usage();
 551                 return 0;
 552         }
 553
 554         if ($opts{i}) {
 555                 # don't update from (remote) repository
 556                 # only re-create index information
 557                 $perform_update=0;
 558         }
 559
 560         -d "feeds" or do {
 561                         mkdir "feeds" or die "Unable to create the feeds directory";
 562                 };
 563
 564         if ( ($#ARGV == -1) or $opts{a}) {
 565                 foreach my $feed (@feeds) {
 566                         my ($type, $name, $src) = @$feed;
 567                         update_feed($type, $name, $src, $perform_update);
 568                 }
 569         } else {
 570                 while ($feed_name = shift @ARGV) {
 571                         foreach my $feed (@feeds) {
 572                                 my ($type, $name, $src) = @$feed;
 573                                 if($feed_name ne $name) {
 574                                         next;
 575                                 }
 576                                 update_feed($type, $name, $src, $perform_update);
 577                         }
 578                 }
 579         }
 580
 581         refresh_config();
 582
 583         return 0;
 584 }
 585
 586 sub usage() {
 587         print <<EOF;
 588 Usage: $0 <command> [options]
 589
 590 Commands:
 591         list [options]: List feeds, their content and revisions (if installed)
 592         Options:
 593             -s :            List of feed names and their URL.
 594             -r <feedname>:  List packages of specified feed.
 595             -d <delimiter>: Use specified delimiter to distinguish rows (default: spaces)
 596
 597         install [options] <package>: Install a package
 598         Options:
 599             -a :           Install all packages from all feeds or from the specified feed using the -p option.
 600             -p <feedname>: Prefer this feed when installing packages.
 601             -d <y|m|n>:    Set default for newly installed packages.
 602
 603         search [options] <substring>: Search for a package
 604         Options:
 605             -r <feedname>: Only search in this feed
 606
 607         uninstall -a|<package>: Uninstall a package
 608         Options:
 609             -a :           Uninstalls all packages.
 610
 611         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
 612         Options:
 613             -a :           Update all feeds listed within feeds.conf. Otherwise the specified feeds will be updated.
 614             -i :           Recreate the index only. No feed update from repository is performed.
 615
 616         clean:             Remove downloaded/generated files.
 617
 618 EOF
 619         exit(1);
 620 }
 621
 622 my %commands = (
 623         'list' => \&list,
 624         'update' => \&update,
 625         'install' => \&install,
 626         'search' => \&search,
 627         'uninstall' => \&uninstall,
 628         'clean' => sub {
 629                 system("rm -rf feeds");
 630         }
 631 );
 632
 633 my $arg = shift @ARGV;
 634 $arg or usage();
 635 parse_config;
 636 foreach my $cmd (keys %commands) {
 637         $arg eq $cmd and do {
 638                 exit(&{$commands{$cmd}}());
 639         };
 640 }
 641 usage();