scripts/metadata.pl

   1 #!/usr/bin/perl
   2 use strict;
   3 my %package;
   4 my %category;
   5
   6 sub parse_target_metadata() {
   7         my ($target, @target, $profile);
   8         while (<>) {
   9                 chomp;
  10                 /^Target:\s*((.+)-(\d+\.\d+))\s*$/ and do {
  11                         my $conf = uc $3.'_'.$2;
  12                         $conf =~ tr/\.-/__/;
  13                         $target = {
  14                                 id => $1,
  15                                 conf => $conf,
  16                                 board => $2,
  17                                 kernel => $3,
  18                                 profiles => []
  19                         };
  20                         push @target, $target;
  21                 };
  22                 /^Target-Name:\s*(.+)\s*$/ and $target->{name} = $1;
  23                 /^Target-Path:\s*(.+)\s*$/ and $target->{path} = $1;
  24                 /^Target-Arch:\s*(.+)\s*$/ and $target->{arch} = $1;
  25                 /^Target-Features:\s*(.+)\s*$/ and $target->{features} = [ split(/\s+/, $1) ];
  26                 /^Target-Description:/ and do {
  27                         my $desc;
  28                         while (<>) {
  29                                 last if /^@@/;
  30                                 $desc .= $_;
  31                         }
  32                         $target->{desc} = $desc;
  33                 };
  34                 /^Linux-Version:\s*(.+)\s*$/ and $target->{version} = $1;
  35                 /^Linux-Release:\s*(.+)\s*$/ and $target->{release} = $1;
  36                 /^Linux-Kernel-Arch:\s*(.+)\s*$/ and $target->{karch} = $1;
  37                 /^Default-Packages:\s*(.+)\s*$/ and $target->{packages} = [ split(/\s+/, $1) ];
  38                 /^Target-Profile:\s*(.+)\s*$/ and do {
  39                         $profile = {
  40                                 id => $1,
  41                                 name => $1,
  42                                 packages => []
  43                         };
  44                         push @{$target->{profiles}}, $profile;
  45                 };
  46                 /^Target-Profile-Name:\s*(.+)\s*$/ and $profile->{name} = $1;
  47                 /^Target-Profile-Packages:\s*(.*)\s*$/ and $profile->{packages} = [ split(/\s+/, $1) ];
  48                 /^Target-Profile-Description:/ and do {
  49                         my $desc;
  50                         while (<>) {
  51                                 last if /^@@/;
  52                                 $desc .= $_;
  53                         }
  54                         $profile->{desc} = $desc;
  55                 };
  56                 /^Target-Profile-Kconfig:/ and $profile->{kconfig} = 1;
  57         }
  58         foreach my $target (@target) {
  59                 @{$target->{profiles}} > 0 or $target->{profiles} = [
  60                         {
  61                                 id => 'Default',
  62                                 name => 'Default',
  63                                 packages => []
  64                         }
  65                 ];
  66         }
  67         return @target;
  68 }
  69
  70 sub parse_package_metadata() {
  71         my $pkg;
  72         my $makefile;
  73         my $src;
  74         while (<>) {
  75                 chomp;
  76                 /^Source-Makefile: \s*(.+\/([^\/]+)\/Makefile)\s*$/ and do {
  77                         $makefile = $1;
  78                         $src = $2;
  79                         undef $pkg;
  80                 };
  81                 /^Package: \s*(.+)\s*$/ and do {
  82                         $pkg = {};
  83                         $pkg->{src} = $src;
  84                         $pkg->{makefile} = $makefile;
  85                         $pkg->{name} = $1;
  86                         $pkg->{default} = "m if ALL";
  87                         $package{$1} = $pkg;
  88                 };
  89                 /^Version: \s*(.+)\s*$/ and $pkg->{version} = $1;
  90                 /^Title: \s*(.+)\s*$/ and $pkg->{title} = $1;
  91                 /^Menu: \s*(.+)\s*$/ and $pkg->{menu} = $1;
  92                 /^Submenu: \s*(.+)\s*$/ and $pkg->{submenu} = $1;
  93                 /^Submenu-Depends: \s*(.+)\s*$/ and $pkg->{submenudep} = $1;
  94                 /^Default: \s*(.+)\s*$/ and $pkg->{default} = $1;
  95                 /^Provides: \s*(.+)\s*$/ and do {
  96                         my @vpkg = split /\s+/, $1;
  97                         foreach my $vpkg (@vpkg) {
  98                                 $package{$vpkg} or $package{$vpkg} = { vdepends => [] };
  99                                 push @{$package{$vpkg}->{vdepends}}, $pkg->{name};
 100                         }
 101                 };
 102                 /^Depends: \s*(.+)\s*$/ and do {
 103                         my @dep = split /\s+/, $1;
 104                         $pkg->{depends} = \@dep;
 105                 };
 106                 /^Category: \s*(.+)\s*$/ and do {
 107                         $pkg->{category} = $1;
 108                         defined $category{$1} or $category{$1} = {};
 109                         defined $category{$1}->{$src} or $category{$1}->{$src} = [];
 110                         push @{$category{$1}->{$src}}, $pkg;
 111                 };
 112                 /^Description: \s*(.*)\s*$/ and do {
 113                         my $desc = "\t\t$1\n\n";
 114                         my $line;
 115                         while ($line = <>) {
 116                                 last if $line =~ /^@@/;
 117                                 $desc .= "\t\t$line";
 118                         }
 119                         $pkg->{description} = $desc;
 120                 };
 121                 /^Config: \s*(.*)\s*$/ and do {
 122                         my $conf = "$1\n";
 123                         my $line;
 124                         while ($line = <>) {
 125                                 last if $line =~ /^@@/;
 126                                 $conf .= "$line";
 127                         }
 128                         $pkg->{config} = $conf;
 129                 }
 130         }
 131         return %category;
 132 }
 133
 134
 135 sub gen_target_mk() {
 136         my @target = parse_target_metadata();
 137
 138         @target = sort {
 139                 $a->{id} cmp $b->{id}
 140         } @target;
 141
 142         foreach my $target (@target) {
 143                 my ($profiles_def, $profiles_eval);
 144                 my $conf = uc $target->{kernel}.'_'.$target->{board};
 145                 $conf =~ tr/\.-/__/;
 146
 147                 foreach my $profile (@{$target->{profiles}}) {
 148                         $profiles_def .= "
 149   define Profile/$conf\_$profile->{id}
 150     ID:=$profile->{id}
 151     NAME:=$profile->{name}
 152     PACKAGES:=".join(" ", @{$profile->{packages}})."\n";
 153                         $profile->{kconfig} and $profiles_def .= "    KCONFIG:=1\n";
 154                         $profiles_def .= "  endef";
 155                         $profiles_eval .= "
 156 \$(eval \$(call AddProfile,$conf\_$profile->{id}))"
 157                 }
 158                 print "
 159 ifeq (\$(CONFIG_LINUX_$conf),y)
 160   define Target
 161     KERNEL:=$target->{kernel}
 162     BOARD:=$target->{board}
 163     BOARDNAME:=$target->{name}
 164     LINUX_VERSION:=$target->{version}
 165     LINUX_RELEASE:=$target->{release}
 166     LINUX_KARCH:=$target->{karch}
 167     DEFAULT_PACKAGES:=".join(" ", @{$target->{packages}})."
 168   endef$profiles_def
 169 endif$profiles_eval
 170
 171 "
 172         }
 173         print "\$(eval \$(call Target))\n";
 174 }
 175
 176 sub target_config_features(@) {
 177         my $ret;
 178
 179         while ($_ = shift @_) {
 180                 /broken/ and $ret .= "\tdepends BROKEN\n";
 181                 /pci/ and $ret .= "\tselect PCI_SUPPORT\n";
 182                 /usb/ and $ret .= "\tselect USB_SUPPORT\n";
 183                 /atm/ and $ret .= "\tselect ATM_SUPPORT\n";
 184                 /pcmcia/ and $ret .= "\tselect PCMCIA_SUPPORT\n";
 185                 /video/ and $ret .= "\tselect VIDEO_SUPPORT\n";
 186                 /squashfs/ and $ret .= "\tselect USES_SQUASHFS\n";
 187                 /jffs2/ and $ret .= "\tselect USES_JFFS2\n";
 188                 /ext2/ and $ret .= "\tselect USES_EXT2\n";
 189         }
 190         return $ret;
 191 }
 192
 193
 194 sub gen_target_config() {
 195         my @target = parse_target_metadata();
 196
 197         @target = sort {
 198                 $a->{name} cmp $b->{name}
 199         } @target;
 200
 201
 202         print <<EOF;
 203 choice
 204         prompt "Target System"
 205         default LINUX_2_4_BRCM
 206
 207 EOF
 208
 209         foreach my $target (@target) {
 210                 my $features = target_config_features(@{$target->{features}});
 211                 my $help = $target->{desc};
 212                 my $kernel = $target->{kernel};
 213                 $kernel =~ tr/./_/;
 214
 215                 chomp $features;
 216                 $features .= "\n";
 217                 if ($help =~ /\w+/) {
 218                         $help =~ s/^\s*/\t  /mg;
 219                         $help = "\thelp\n$help";
 220                 } else {
 221                         undef $help;
 222                 }
 223
 224                 print <<EOF
 225 config LINUX_$target->{conf}
 226         bool "$target->{name}"
 227         select $target->{arch}
 228         select LINUX_$kernel
 229 $features$help
 230
 231 EOF
 232         }
 233
 234         print <<EOF;
 235 if DEVEL
 236
 237 config LINUX_2_6_ARM
 238         bool "UNSUPPORTED little-endian arm platform"
 239         depends BROKEN
 240         select LINUX_2_6
 241         select arm
 242
 243 config LINUX_2_6_CRIS
 244         bool "UNSUPPORTED cris platform"
 245         depends BROKEN
 246         select LINUX_2_6
 247         select cris
 248
 249 config LINUX_2_6_M68K
 250         bool "UNSUPPORTED m68k platform"
 251         depends BROKEN
 252         select LINUX_2_6
 253         select m68k
 254
 255 config LINUX_2_6_SH3
 256         bool "UNSUPPORTED little-endian sh3 platform"
 257         depends BROKEN
 258         select LINUX_2_6
 259         select sh3
 260
 261 config LINUX_2_6_SH3EB
 262         bool "UNSUPPORTED big-endian sh3 platform"
 263         depends BROKEN
 264         select LINUX_2_6
 265         select sh3eb
 266
 267 config LINUX_2_6_SH4
 268         bool "UNSUPPORTED little-endian sh4 platform"
 269         depends BROKEN
 270         select LINUX_2_6
 271         select sh4
 272
 273 config LINUX_2_6_SH4EB
 274         bool "UNSUPPORTED big-endian sh4 platform"
 275         depends BROKEN
 276         select LINUX_2_6
 277         select sh4eb
 278
 279 config LINUX_2_6_SPARC
 280         bool "UNSUPPORTED sparc platform"
 281         depends BROKEN
 282         select LINUX_2_6
 283         select sparc
 284
 285 endif
 286
 287 endchoice
 288
 289 choice
 290         prompt "Target Profile"
 291
 292 EOF
 293
 294         foreach my $target (@target) {
 295                 my $profiles = $target->{profiles};
 296
 297                 foreach my $profile (@$profiles) {
 298                         print <<EOF;
 299 config LINUX_$target->{conf}_$profile->{id}
 300         bool "$profile->{name}"
 301         depends LINUX_$target->{conf}
 302 EOF
 303                         $profile->{kconfig} and print "\tselect PROFILE_KCONFIG\n";
 304                         my %pkgs;
 305                         foreach my $pkg (@{$target->{packages}}, @{$profile->{packages}}) {
 306                                 $pkgs{$pkg} = 1;
 307                         }
 308                         foreach my $pkg (keys %pkgs) {
 309                                 print "\tselect DEFAULT_$pkg\n" unless ($pkg =~ /^-/ or $pkgs{"-$pkg"});
 310                         }
 311                         print "\n";
 312                 }
 313         }
 314
 315         print "endchoice\n";
 316 }
 317
 318 sub find_package_dep($$) {
 319         my $pkg = shift;
 320         my $name = shift;
 321         my $deps = ($pkg->{vdepends} or $pkg->{depends});
 322
 323         return 0 unless defined $deps;
 324         foreach my $dep (@{$deps}) {
 325                 return 1 if $dep eq $name;
 326                 return 1 if ($package{$dep} and (find_package_dep($package{$dep},$name) == 1));
 327         }
 328         return 0;
 329 }
 330
 331 sub package_depends($$) {
 332         my $a = shift;
 333         my $b = shift;
 334         my $ret;
 335
 336         return 0 if ($a->{submenu} ne $b->{submenu});
 337         if (find_package_dep($a, $b->{name}) == 1) {
 338                 $ret = 1;
 339         } elsif (find_package_dep($b, $a->{name}) == 1) {
 340                 $ret = -1;
 341         } else {
 342                 return 0;
 343         }
 344         return $ret;
 345 }
 346
 347 sub mconf_depends($$) {
 348         my $depends = shift;
 349         my $only_dep = shift;
 350         my $res;
 351
 352         $depends or return;
 353         my @depends = @$depends;
 354         foreach my $depend (@depends) {
 355                 my $m = "depends";
 356                 $depend =~ s/^([@\+]+)//;
 357                 my $flags = $1;
 358                 my $vdep;
 359
 360                 if ($vdep = $package{$depend}->{vdepends}) {
 361                         $depend = join("||", map { "PACKAGE_".$_ } @$vdep);
 362                 } else {
 363                         $flags =~ /\+/ and do {
 364                                 next if $only_dep;
 365                                 $m = "select";
 366
 367                                 # Menuconfig will not treat 'select FOO' as a real dependency
 368                                 # thus if FOO depends on other config options, these dependencies
 369                                 # will not be checked. To fix this, we simply emit all of FOO's
 370                                 # depends here as well.
 371                                 $package{$depend} and $res .= mconf_depends($package{$depend}->{depends}, 1);
 372                         };
 373                         $flags =~ /@/ or $depend = "PACKAGE_$depend";
 374                 }
 375                 $res .= "\t\t$m $depend\n";
 376         }
 377         return $res;
 378 }
 379
 380 sub print_package_config_category($) {
 381         my $cat = shift;
 382         my %menus;
 383         my %menu_dep;
 384
 385         return unless $category{$cat};
 386
 387         print "menu \"$cat\"\n\n";
 388         my %spkg = %{$category{$cat}};
 389
 390         foreach my $spkg (sort {uc($a) cmp uc($b)} keys %spkg) {
 391                 foreach my $pkg (@{$spkg{$spkg}}) {
 392                         my $menu = $pkg->{submenu};
 393                         if ($menu) {
 394                                 $menu_dep{$menu} or $menu_dep{$menu} = $pkg->{submenudep};
 395                         } else {
 396                                 $menu = 'undef';
 397                         }
 398                         $menus{$menu} or $menus{$menu} = [];
 399                         push @{$menus{$menu}}, $pkg;
 400                         print "\tconfig DEFAULT_".$pkg->{name}."\n";
 401                         print "\t\tbool\n\n";
 402                 }
 403         }
 404         my @menus = sort {
 405                 ($a eq 'undef' ?  1 : 0) or
 406                 ($b eq 'undef' ? -1 : 0) or
 407                 ($a cmp $b)
 408         } keys %menus;
 409
 410         foreach my $menu (@menus) {
 411                 my @pkgs = sort {
 412                         package_depends($a, $b) or
 413                         ($a->{name} cmp $b->{name})
 414                 } @{$menus{$menu}};
 415                 if ($menu ne 'undef') {
 416                         $menu_dep{$menu} and print "if $menu_dep{$menu}\n";
 417                         print "menu \"$menu\"\n";
 418                 }
 419                 foreach my $pkg (@pkgs) {
 420                         my $title = $pkg->{name};
 421                         my $c = (72 - length($pkg->{name}) - length($pkg->{title}));
 422                         if ($c > 0) {
 423                                 $title .= ("." x $c). " ". $pkg->{title};
 424                         }
 425                         print "\t";
 426                         $pkg->{menu} and print "menu";
 427                         print "config PACKAGE_".$pkg->{name}."\n";
 428                         print "\t\ttristate \"$title\"\n";
 429                         print "\t\tdefault y if DEFAULT_".$pkg->{name}."\n";
 430                         foreach my $default (split /\s*,\s*/, $pkg->{default}) {
 431                                 print "\t\tdefault $default\n";
 432                         }
 433                         print mconf_depends($pkg->{depends}, 0);
 434                         print "\t\thelp\n";
 435                         print $pkg->{description};
 436                         print "\n";
 437
 438                         $pkg->{config} and print $pkg->{config}."\n";
 439                 }
 440                 if ($menu ne 'undef') {
 441                         print "endmenu\n";
 442                         $menu_dep{$menu} and print "endif\n";
 443                 }
 444         }
 445         print "endmenu\n\n";
 446
 447         undef $category{$cat};
 448 }
 449
 450 sub gen_package_config() {
 451         parse_package_metadata();
 452         print_package_config_category 'Base system';
 453         foreach my $cat (keys %category) {
 454                 print_package_config_category $cat;
 455         }
 456 }
 457
 458 sub parse_command() {
 459         my $cmd = shift @ARGV;
 460         for ($cmd) {
 461                 /^target_mk$/ and return gen_target_mk();
 462                 /^target_config$/ and return gen_target_config();
 463                 /^package_config$/ and return gen_package_config();
 464         }
 465         print <<EOF
 466 Available Commands:
 467         $0 target_mk [file]             Target metadata in makefile format
 468         $0 target_config [file]         Target metadata in Kconfig format
 469         $0 package_config [file]        Package metadata in Kconfig format
 470 EOF
 471 }
 472
 473 parse_command();