package/base-files/files/bin/ipcalc.sh

   1 #!/bin/sh
   2
   3 awk -f - $* <<EOF
   4 function bitcount(c) {
   5         c=and(rshift(c, 1),0x55555555)+and(c,0x55555555)
   6         c=and(rshift(c, 2),0x33333333)+and(c,0x33333333)
   7         c=and(rshift(c, 4),0x0f0f0f0f)+and(c,0x0f0f0f0f)
   8         c=and(rshift(c, 8),0x00ff00ff)+and(c,0x00ff00ff)
   9         c=and(rshift(c,16),0x0000ffff)+and(c,0x0000ffff)
  10         return c
  11 }
  12
  13 function ip2int(ip) {
  14         for (ret=0,n=split(ip,a,"\."),x=1;x<=n;x++) ret=or(lshift(ret,8),a[x])
  15         return ret
  16 }
  17
  18 function int2ip(ip,ret,x) {
  19         ret=and(ip,255)
  20         ip=rshift(ip,8)
  21         for(;x<3;ret=and(ip,255)"."ret,ip=rshift(ip,8),x++);
  22         return ret
  23 }
  24
  25 BEGIN {
  26         slpos=index(ARGV[1],"/")
  27         if (slpos == 0) {
  28                 ipaddr=ip2int(ARGV[1])
  29                 netmask=ip2int(ARGV[2])
  30         } else {
  31                 ipaddr=ip2int(substr(ARGV[1],0,slpos-1))
  32                 netmask=compl(2**(32-int(substr(ARGV[1],slpos+1)))-1)
  33                 ARGV[4]=ARGV[3]
  34                 ARGV[3]=ARGV[2]
  35         }
  36
  37         network=and(ipaddr,netmask)
  38         broadcast=or(network,compl(netmask))
  39
  40         start=or(network,and(ip2int(ARGV[3]),compl(netmask)))
  41         limit=network+1
  42         if (start<limit) start=limit
  43
  44         end=start+ARGV[4]
  45         limit=or(network,compl(netmask))-1
  46         if (end>limit) end=limit
  47
  48         print "IP="int2ip(ipaddr)
  49         print "NETMASK="int2ip(netmask)
  50         print "BROADCAST="int2ip(broadcast)
  51         print "NETWORK="int2ip(network)
  52         print "PREFIX="32-bitcount(compl(netmask))
  53
  54         # range calculations:
  55         # ipcalc <ip> <netmask> <start> <num>
  56
  57         if (ARGC > 3) {
  58                 print "START="int2ip(start)
  59                 print "END="int2ip(end)
  60         }
  61 }
  62 EOF