package/base-files/files/bin/ipcalc.sh

   1 #!/bin/sh
   2
   3 awk -f - $* <<EOF
   4 function bitcount(c) {
   5         c=and(rshift(c, 1),0x55555555)+and(c,0x55555555)
   6         c=and(rshift(c, 2),0x33333333)+and(c,0x33333333)
   7         c=and(rshift(c, 4),0x0f0f0f0f)+and(c,0x0f0f0f0f)
   8         c=and(rshift(c, 8),0x00ff00ff)+and(c,0x00ff00ff)
   9         c=and(rshift(c,16),0x0000ffff)+and(c,0x0000ffff)
  10         return c
  11 }
  12
  13 function ip2int(ip) {
  14         for (ret=0,n=split(ip,a,"\."),x=1;x<=n;x++) ret=or(lshift(ret,8),a[x])
  15         return ret
  16 }
  17
  18 function int2ip(ip,ret,x) {
  19         ret=and(ip,255)
  20         ip=rshift(ip,8)
  21         for(;x<3;ret=and(ip,255)"."ret,ip=rshift(ip,8),x++);
  22         return ret
  23 }
  24
  25 function compl32(v) {
  26         ret=xor(v, 0xffffffff)
  27         return ret
  28 }
  29
  30 BEGIN {
  31         slpos=index(ARGV[1],"/")
  32         if (slpos == 0) {
  33                 ipaddr=ip2int(ARGV[1])
  34                 netmask=ip2int(ARGV[2])
  35         } else {
  36                 ipaddr=ip2int(substr(ARGV[1],0,slpos-1))
  37                 netmask=compl32(2**(32-int(substr(ARGV[1],slpos+1)))-1)
  38                 ARGV[4]=ARGV[3]
  39                 ARGV[3]=ARGV[2]
  40         }
  41
  42         network=and(ipaddr,netmask)
  43         broadcast=or(network,compl32(netmask))
  44
  45         start=or(network,and(ip2int(ARGV[3]),compl32(netmask)))
  46         limit=network+1
  47         if (start<limit) start=limit
  48
  49         end=start+ARGV[4]
  50         limit=or(network,compl32(netmask))-1
  51         if (end>limit) end=limit
  52
  53         print "IP="int2ip(ipaddr)
  54         print "NETMASK="int2ip(netmask)
  55         print "BROADCAST="int2ip(broadcast)
  56         print "NETWORK="int2ip(network)
  57         print "PREFIX="32-bitcount(compl32(netmask))
  58
  59         # range calculations:
  60         # ipcalc <ip> <netmask> <start> <num>
  61
  62         if (ARGC > 3) {
  63                 print "START="int2ip(start)
  64                 print "END="int2ip(end)
  65         }
  66 }
  67 EOF